win32汇编
win32汇编 创建窗口的代码小甲鱼 讲课的代码 给我只要 创建窗口代码
.386
.model flat,stdcall
option casemap:none
include windows.inc
include gdi32.inc
includelib gdi32.lib
include user32.inc
includelib user32.lib
include kernel32.inc
includelib kernel32.lib
; 数据段
.data? ;变量
hInstance dd ?
hWinMain dd ?
.const ;常量
szClassName db 'MyClass',0
szCaptionMain db '窗口',0
szText db '000000000000',0
; 代码段
.code
;********************************************************************
; 窗口过程 载入时执行
;********************************************************************
_ProcWinMain proc uses ebx edi esi hWnd,uMsg,wParam,lParam
local @stPs:PAINTSTRUCT
local @stRect:RECT
local @hDc
mov eax,uMsg
.if eax == WM_PAINT ;执行窗口的属性
invoke BeginPaint,hWnd,addr @stPs
mov @hDc,eax
invoke GetClientRect,hWnd,addr @stRect
invoke DrawText,@hDc,addr szText,-1,addr @stRect,\;显示文字到窗口
DT_SINGLELINE or DT_CENTER or DT_VCENTER
invoke EndPaint,hWnd,addr @stPs
.elseif eax == WM_CLOSE
invoke DestroyWindow,hWinMain
invoke PostQuitMessage,NULL
.else
invoke DefWindowProc,hWnd,uMsg,wParam,lParam ;键盘 鼠标 等消息
ret
.endif
xor eax,eax
ret
_ProcWinMain endp
_WinMain proc
local @stWndClass:WNDCLASSEX
local @stMsg:MSG
invoke GetModuleHandle,NULL
mov hInstance,eax
invoke RtlZeroMemory,addr @stWndClass,sizeof @stWndClass
;********************************************************************
;注册窗口类
;********************************************************************
invoke LoadCursor,0,IDC_ARROW ;加载箭头形指针句柄
mov @stWndClass.hCursor,eax ;鼠标指针赋值
push hInstance
pop @stWndClass.hInstance ;窗口句柄赋值
mov @stWndClass.cbSize,sizeof WNDCLASSEX ;结构大小
mov @stWndClass.style,CS_HREDRAW or CS_VREDRAW ;设置窗口样式
mov @stWndClass.lpfnWndProc,offset _ProcWinMain ;设置回调函数，也就是窗口消息处理过程
mov @stWndClass.hbrBackground,COLOR_WINDOW + 1
mov @stWndClass.lpszClassName,offset szClassName
invoke RegisterClassEx,addr @stWndClass
;********************************************************************
;建立并显示窗口
;********************************************************************
invoke CreateWindowEx,WS_EX_CLIENTEDGE,offset szClassName,offset szCaptionMain,\ ;窗口名称
WS_OVERLAPPEDWINDOW,\
100,100,600,400,\
NULL,NULL,hInstance,NULL
mov hWinMain,eax
invoke ShowWindow,hWinMain,SW_SHOWNORMAL ;显示窗口
invoke UpdateWindow,hWinMain ;刷新窗口
; 消息循环
.while TRUE
invoke GetMessage,addr @stMsg,NULL,0,0
.break .if eax == 0
invoke TranslateMessage,addr @stMsg
invoke DispatchMessage,addr @stMsg
.endw
ret
_WinMain endp
start:
call _WinMain
invoke ExitProcess,NULL
end start
页:
[1]