设为首页收藏本站
切换到窄版

鱼C论坛

 找回密码
 立即注册
鱼C论坛»论坛 › 编程语言专区 › 汇编语言交流 › 小白求助
返回列表 发新帖
查看: 3392|回复: 2

小白求助

[复制链接]
陌镜零
发表于 2018-12-16 17:29:48 | 显示全部楼层 |阅读模式

马上注册，结交更多好友，享用更多功能^_^

您需要 登录 才可以下载或查看，没有账号？立即注册

x
第一个题目：计算从1到20的累加和，以十进制的方式显示在屏幕上
第二个题目：在80*25的屏幕上，以多种颜色显示多种字符
求大佬这两道题怎么写？
还有DOSBox 0.74怎么在屏幕上显示程序运行结果？
小甲鱼最新课程 -> https://ilovefishc.com
回复

使用道具 举报

人造人
发表于 2018-12-16 22:45:36 | 显示全部楼层
  1. assume cs:code, ds:data

  3. data segment
  4. buf        db 512 dup(?)
  5. stack        db 512 dup(?)
  6. stack_top:
  7. data ends

  9. code segment
  10. ; void PutChar(uint8_t x, uint8_t y, char ch, uint8_t attr);
  11. PutChar:
  12.         push        bp
  13.         mov        bp, sp
  14.         push        di
  15.         push        es
  16.        
  17.         mov        ax, 0b800h
  18.         mov        es, ax
  19.         mov        dl, [bp + 6]        ; y
  20.         mov        al, 160
  21.         mul        dl
  22.         mov        di, ax
  23.         mov        dl, [bp + 4]        ; x
  24.         mov        al, 2
  25.         mul        dl
  26.         add        di, ax
  27.        
  28.         mov        al, [bp + 8]        ; ch
  29.         mov        ah, [bp + 10]        ; attr
  30.         mov        es:[di], ax
  31.        
  32.         mov        bh, 0        ; 显示页码
  33.         mov        dh, [bp + 6]        ; y
  34.         mov        dl, [bp + 4]        ; x
  35.         add        dl, 1
  36.         mov        ah, 2        ; 设置光标位置
  37.         int        10h
  38.        
  39.         pop        es
  40.         pop        di
  41.         mov        sp, bp
  42.         pop        bp
  43.         ret

  45. ; void PutString(uint8_t x, uint8_t y, char *str, uint8_t attr);
  46. PutString:
  47.         push        bp
  48.         mov        bp, sp
  49.         push        bx
  50.         push        si
  51.         push        di
  52.        
  53.         mov        si, [bp + 4]        ; x
  54.         mov        di, [bp + 6]        ; y
  55.         mov        bx, [bp + 8]        ; str
  56. @@:
  57.         cmp        byte ptr [bx], 0
  58.         je        @F
  59.         push        [bp + 10]        ; attr
  60.         xor        ah, ah
  61.         mov        al, [bx]
  62.         push        ax                ; ch
  63.         push        di                ; y
  64.         push        si                ; x
  65.         call        PutChar
  66.         add        sp, 8
  67.         inc        si
  68.         inc        bx
  69.         jmp        @B
  70. @@:
  71.         pop        di
  72.         pop        si
  73.         pop        bx
  74.         mov        sp, bp
  75.         pop        bp
  76.         ret

  78. ; void NumberToString(uint16_t number, char *buffer);
  79. NumberToString:
  80.         push        bp
  81.         mov        bp, sp
  82.         push        bx
  83.         push        si
  84.         push        di
  85.        
  86.         mov        di, [bp + 6]        ; buffer
  87.         mov        ax, [bp + 4]        ; number
  88.         xor        dx, dx
  89.         ;mov        cx, 16
  90.         mov        cx, 10                ; 现在是要十进制
  91. @@:
  92.         div        cx
  93.         mov        dh, dl
  94.         add        dl, '0'
  95.         cmp        dh, 10
  96.         jb        @1
  97.         mov        dl, dh
  98.         sub        dl, 10
  99.         add        dl, 'A'
  100. @1:
  101.         mov        [di], dl
  102.         inc        di
  103.         xor        dx, dx
  104.         cmp        ax, 0
  105.         jne        @B
  106.         mov        byte ptr [di], 0        ; '\0'
  107.        
  108.         ; 下面翻转字符串
  109.         dec        di
  110.         mov        si, [bp + 6]        ; buffer
  111. @@:
  112.         cmp        si, di
  113.         jge        @F
  114.         mov        ah, [si]
  115.         mov        al, [di]
  116.         mov        [si], al
  117.         mov        [di], ah
  118.         inc        si
  119.         dec        di
  120.         jmp        @B
  121. @@:
  122.         pop        di
  123.         pop        si
  124.         pop        bx
  125.         mov        sp, bp
  126.         pop        bp
  127.         ret
  128. start:
  129.         mov        ax, data
  130.         mov        ds, ax
  131.         mov        ss, ax
  132.         mov        sp, stack_top
  133.        
  134.         mov        cx, 1
  135.         xor        ax, ax
  136. L:
  137.         add        ax, cx
  138.         inc        cx
  139.         cmp        cx, 20
  140.         jbe        L
  141.        
  142.         mov        bx, offset buf
  143.         push        bx                ; buffer
  144.         push        ax                ; number
  145.         call        NumberToString
  146.         add        sp, 4
  147.        
  148.         mov        ax, 07h
  149.         push        ax                ; attr
  150.         mov        ax, offset buf
  151.         push        ax                ; str
  152.         xor        ax, ax
  153.         push        ax                ; y
  154.         push        ax                ; x
  155.         call        PutString
  156.         add        sp, 8
  157.        
  158.         mov        ax, 4c00h
  159.         int        21h
  160. code ends
  161. end start
复制代码
小甲鱼最新课程 -> https://ilovefishc.com
回复 支持 反对

使用道具 举报

人造人
发表于 2018-12-16 22:52:58 | 显示全部楼层
  1. assume cs:code, ds:data

  3. data segment
  4. msg0        db 'C', 0
  5. msg1        db 'C++', 0
  6. msg2        db 'Java', 0
  7. msg3        db 'Python', 0

  9. stack        db 512 dup(?)
  10. stack_top:
  11. data ends

  13. code segment
  14. ; void PutChar(uint8_t x, uint8_t y, char ch, uint8_t attr);
  15. PutChar:
  16.         push        bp
  17.         mov        bp, sp
  18.         push        di
  19.         push        es
  20.        
  21.         mov        ax, 0b800h
  22.         mov        es, ax
  23.         mov        dl, [bp + 6]        ; y
  24.         mov        al, 160
  25.         mul        dl
  26.         mov        di, ax
  27.         mov        dl, [bp + 4]        ; x
  28.         mov        al, 2
  29.         mul        dl
  30.         add        di, ax
  31.        
  32.         mov        al, [bp + 8]        ; ch
  33.         mov        ah, [bp + 10]        ; attr
  34.         mov        es:[di], ax
  35.        
  36.         mov        bh, 0        ; 显示页码
  37.         mov        dh, [bp + 6]        ; y
  38.         mov        dl, [bp + 4]        ; x
  39.         add        dl, 1
  40.         mov        ah, 2        ; 设置光标位置
  41.         int        10h
  42.        
  43.         pop        es
  44.         pop        di
  45.         mov        sp, bp
  46.         pop        bp
  47.         ret

  49. ; void PutString(uint8_t x, uint8_t y, char *str, uint8_t attr);
  50. PutString:
  51.         push        bp
  52.         mov        bp, sp
  53.         push        bx
  54.         push        si
  55.         push        di
  56.        
  57.         mov        si, [bp + 4]        ; x
  58.         mov        di, [bp + 6]        ; y
  59.         mov        bx, [bp + 8]        ; str
  60. @@:
  61.         cmp        byte ptr [bx], 0
  62.         je        @F
  63.         push        [bp + 10]        ; attr
  64.         xor        ah, ah
  65.         mov        al, [bx]
  66.         push        ax                ; ch
  67.         push        di                ; y
  68.         push        si                ; x
  69.         call        PutChar
  70.         add        sp, 8
  71.         inc        si
  72.         inc        bx
  73.         jmp        @B
  74. @@:
  75.         pop        di
  76.         pop        si
  77.         pop        bx
  78.         mov        sp, bp
  79.         pop        bp
  80.         ret

  82. start:
  83.         mov        ax, data
  84.         mov        ds, ax
  85.         mov        ss, ax
  86.         mov        sp, stack_top
  87.        
  88.         mov        ax, 09h
  89.         push        ax                ; attr
  90.         mov        ax, offset msg0
  91.         push        ax                ; str
  92.         mov        ax, 0
  93.         push        ax                ; y
  94.         xor        ax, ax
  95.         push        ax                ; x
  96.         call        PutString
  97.         add        sp, 8
  98.        
  99.         mov        ax, 0Ah
  100.         push        ax                ; attr
  101.         mov        ax, offset msg1
  102.         push        ax                ; str
  103.         mov        ax, 1
  104.         push        ax                ; y
  105.         xor        ax, ax
  106.         push        ax                ; x
  107.         call        PutString
  108.         add        sp, 8
  109.        
  110.         mov        ax, 0Ch
  111.         push        ax                ; attr
  112.         mov        ax, offset msg2
  113.         push        ax                ; str
  114.         mov        ax, 2
  115.         push        ax                ; y
  116.         xor        ax, ax
  117.         push        ax                ; x
  118.         call        PutString
  119.         add        sp, 8
  120.        
  121.         mov        ax, 0Eh
  122.         push        ax                ; attr
  123.         mov        ax, offset msg3
  124.         push        ax                ; str
  125.         mov        ax, 3
  126.         push        ax                ; y
  127.         xor        ax, ax
  128.         push        ax                ; x
  129.         call        PutString
  130.         add        sp, 8
  131.        
  132.         mov        ax, 4c00h
  133.         int        21h
  134. code ends
  135. end start
复制代码
小甲鱼最新课程 -> https://ilovefishc.com
回复 支持 反对

使用道具 举报

返回列表 发新帖
高级模式
B Color Image Link Quote Code Smilies
您需要登录后才可以回帖 登录 | 立即注册

本版积分规则

小黑屋|手机版|Archiver|鱼C工作室 ( 粤ICP备18085999号-1 | 粤公网安备 44051102000585号)

GMT+8, 2025-6-10 08:51

Powered by Discuz! X3.4

© 2001-2023 Discuz! Team.

快速回复 返回顶部 返回列表