汇编 内存之间 移动 实验7

︵ゞ痴．想

assume cs:code

data segment
  db '1975','1976','1977','1978','1979','1980','1981','1982','1983'
  db '1984','1985','1986','1987','1988','1989','1990','1991','1992'
  db '1993','1994','1995'
  ;21个字符   84

  dd 16,22,382,1356,2390,8000,16000,24486,50065,97479,140417,197514
  dd 345980,590827,803530,1183000,1843000,2759000,3753000,4649000,5937000
  ;21个双字   168

  dw 3,7,9,13,28,38,130,220,476,778,1001,1442,2258,2793,4037,5635,8226
  dw 11542,14430,15257,17800
  ;21个字型    210

data ends

tihuan segment
  db 21 dup ('year summ ne ??')
tihuan ends

code segment
start:mov ax,data
       mov ds,ax
       mov ax,tihuan
       mov es,ax
       mov cx,21
       mov bx,0
       mov si,0

       ;年份
a:   mov ax,ds:[bx]                      ;mov word ptr es:[si],ds:[bx]   之前用这个做不行的 是为什么呢 其他代码都没错了
       mov dx,ds:[bx+2]
       mov word ptr es:[si],ax
       mov word ptr es:[si+2],dx

       ;收入
       mov ax,ds:[bx+84]                ;mov dword ptr es:[si+5],ds:[bx+84]
       mov dx,ds:[bx+86]
       mov word ptr es:[si+5],ax
       mov word ptr es:[si+7],dx

       ;人数
       mov ax,ds:[bx+168]               ;mov word ptr es:[si+10],ds:[bx+168]
       mov word ptr es:[si+10],ax

       ;人均收入
       mov ax,ds:[bx+84]
       mov dx,ds:[bx+86]
       div  word ptr ds:[bx+168]
       mov es:[si+13],ax


       ;循环
       add bx,4
       add si,15

       loop a

       mov ax,4c00h
       int 21h



code ends
end start

wAterLoo

mov word ptr es:[si],ds:[bx]，
数据无法从一个内存块(A)移动到另一个内存块(B)
从微机的角度上看,数据从存储器取出后会进入数据总线，再由数据总线进入寄存器，其次进入B
你想想，会有从A到B直接相连的数据总线吗？
假设有10个内存块（A,B,C,D,E,F,G,H,I,J）
我想把A的数据移动到B，那么有一根总线可以完成
我想把A的数据移动到C，那又要一根总线
我想把A的数据移动到D，那又要一根总线
同理，如果这10个内存块能够互相访问，你觉得要多少根总线呢？
而且1KB的内存就有1024个字节（也就是我上面说的内存块）
这显然不实际，所以计算机不能直接从一个内存块向另一个内存块转移数据

︵ゞ痴．想

是不能直接 内存之间移动吗？
还是我什么用法错误了
用寄存器 移动是可以的

︵ゞ痴．想

报错是报 非法内存操作。。。。。

黄文军

不能直接内存移动,视频上好像有

/li雷文

两个操作数不能同时为段寄存器 这是intel的规定

莫名其妙

说白了   就是没有 mov  **: [X],**:[X] 这样的语句!~