一小段汇编求助（小甲鱼的课程中）

chanchaw

小甲鱼汇编视频课程中的064课程中。
要求做一个将一个字符串无条件转换为大写的程序。
完全代码为：

assume cs:code
code segment
start:
        ;代码段一
        mov ax,cs              
        mov ds,ax              ;上面2行代码为设置源头寄存器的段地址寄存器为当前程序的代码段的首地址
        mov si,offset capital  ;本行代码翻译为设置capital的地址作为ds:si中的偏移地址
                               ;上面3行代码为设置源头寄存器ds:si的地址指向子程序capital的首地址
        
        mov ax,0
        mov es,ax
        mov ax,200h            
        mov di,ax              ;当前认为地址0:200处为一个安全的内存地址，即将会把capital子程序复制到以0:200为首的一段连续的内存地址中
        
        
        mov cx,offset capitalends - offset capital   ;设置CX即下面的movsb的循环次数为capital子程序的总长度
        cld                   ;设置movsb指令的方向为正方向（向后）
        rep movsb             ;开始循环cx次，每次从源地址拷贝一个字节的数据到目的地址上。源地址和目的地址同时自动累加一个字节的长度
        ;上面一整段代码作用是将转换为大写的子程序安装到系统中一段安全的内存中
        
        
        ;代码段二
        mov ax,0
        mov es,ax
        mov word ptr es:[7ch*4],200h
        mov word ptr es:[7ch*4+2],0h
        ;上面一段代码的作用是将中断向量表中7ch位置上的地址指向安全的内存段0:200处
        
        
        mov ax,4c00h
        int 21h
        
capital:
        push cx
        push si
        
change:
        mov cl,[si]
        mov ch,0
        jcxz ok
        and byte ptr [si],11011111b
        inc si
        jmp short change
        
ok:
        pop si
        pop cx
        iret

capitalends:nop
        
code ends
end start

我现在想问
change:
        mov cl,[si]
        mov ch,0
        jcxz ok
        and byte ptr [si],11011111b
        inc si
        jmp short change

这一段程序如何理解。
inc si   让si+1    怎么能够+到0，从而跳转出去呢？？
很不理解。
望高人指点

chanchaw

fuck   
问完就想起来了。
字符串是以0结尾的。。。。