求助

liuyanjun

求助，汇编语言利用循环指令计算任意三角形面积，要求三角形的底和高，通过键盘输入，面积值能够显示输出(用ASM软件进行编译的）

人造人

1. sh-5.2$ cat main.s
   
2.     .section    .text
   
3. 
   
4. # long long atoq(const char *ptr);
   
5. atoq:
   
6.     xorq    %rax, %rax
   
7.     xorq    %rcx, %rcx
   
8. 1:  movb    (%rdi), %cl
   
9.     cmpb    $'0', %cl
   
10.     jb      1f
    
11.     cmpb    $'9', %cl
    
12.     ja      1f
    
13.     subq    $'0', %rcx
    
14.     movq    $10, %rdx
    
15.     mulq    %rdx
    
16.     addq    %rcx, %rax
    
17.     incq    %rdi
    
18.     jmp     1b
    
19. 1:  movq    %rdi, %rdx
    
20.     retq
    
21. 
    
22. # long long qtoa(char *ptr, long long value);
    
23. qtoa:
    
24.     movq    %rsi, %rax
    
25.     movq    %rdi, %rsi
    
26.     movq    $10, %rcx
    
27. 1:  xorq    %rdx, %rdx
    
28.     divq    %rcx
    
29.     addq    $'0', %rdx
    
30.     movb    %dl, (%rdi)
    
31.     incq    %rdi
    
32.     cmpq    $0, %rax
    
33.     jne     1b
    
34.     movq    %rdi, %rax
    
35.     subq    %rsi, %rax
    
36.     decq    %rdi
    
37. 1:  movb    (%rdi), %dh
    
38.     movb    (%rsi), %dl
    
39.     movb    %dh, (%rsi)
    
40.     movb    %dl, (%rdi)
    
41.     incq    %rsi
    
42.     decq    %rdi
    
43.     cmpq    %rsi, %rdi
    
44.     ja      1b
    
45.     retq
    
46. 
    
47.     .global     _start
    
48. _start:
    
49.     subq    $1024, %rsp
    
50. 
    
51.     movq    $0, %rax    # sys_read
    
52.     movq    $0, %rdi    # stdin
    
53.     movq    %rsp, %rsi  # buf
    
54.     movq    $1023, %rdx # count
    
55.     syscall
    
56. 
    
57.     # buf[--count] = '\0';
    
58.     decq    %rax
    
59.     movb    $0, (%rsp, %rax)
    
60. 
    
61.     movq    %rsp, %rdi
    
62.     callq   atoq
    
63.     movq    %rax, %r12
    
64.     movq    %rdx, %rdi
    
65.     incq    %rdi
    
66.     callq   atoq
    
67.     movq    %rax, %r13
    
68. 
    
69.     movq    %r12, %rax
    
70.     mulq    %r13
    
71. 
    
72.     movq    $2, %rcx
    
73.     divq    %rcx
    
74. 
    
75.     movq    %rsp, %rdi
    
76.     movq    %rax, %rsi
    
77.     callq   qtoa
    
78. 
    
79.     movb    $'\n', (%rsp, %rax)
    
80.     incq    %rax
    
81.     movq    %rax, %rcx
    
82. 
    
83.     movq    $1, %rax    # sys_write
    
84.     movq    $1, %rdi    # stdout
    
85.     movq    %rsp, %rsi  # buf
    
86.     movq    %rcx, %rdx  # count
    
87.     syscall
    
88. 
    
89. 1:  movq    $60, %rax   # sys_exit
    
90.     xorq    %rdi, %rdi  # error_code
    
91.     syscall
    
92.     jmp     1b
    
93. sh-5.2$ as -g -o main.o main.s
    
94. sh-5.2$ ld -o main main.o
    
95. sh-5.2$ ./main
    
96. 10 20
    
97. 100
    
98. sh-5.2$ ./main
    
99. 19 8
    
100. 76
     
101. sh-5.2$ ./main
     
102. 19 7
     
103. 66
     
104. sh-5.2$
     

复制代码