第九章实验9，自己写的程序，显示不出最后的m和！运行中还修改了data段中的数据

chgtx

assume cs:code,ds:data,ss:stack

data segment
  db'welcome to masm!'
  db 2h,24h,71h
data ends

stack segment
  dw 8 dup(0)
stack ends

code segment
start:mov ax,data
        mov ds,ax             ；将数据段地址给ds
        mov ax,0b872h   
        mov es,ax              ；将显示缓冲区段地址给es
        mov bx,0
        mov si,0
        mov di,0
        mov bp,0           
        mov sp,16
          
        mov cx,3
s0:    push cx
        mov cx,16
s1:    mov ax,[bx]
        mov ah,16[di]      ;di索引颜色属性
        mov es:[bp][si],ax ；si索引行地址，bp索引显示缓冲区行中字符位置
        add bp,2
        inc bx
                
        loop s1
          
        mov bx,0
        mov bp,0          
        pop cx
        add si,0a0h     ；换行
        inc di
        loop s0
          
        mov ax,4c00h
        int 21h
          
code ends
end start

chgtx

没有mov ax,stack
      mov ss,ax

taochen

assume cs:code,ds:data,ss:stack
data segment
        db 'welcome to masm!'  ;定义要显示的字符串(共16字节)
        db 02h,24h,71h    ;定义三种颜色属性
data ends
stack segment
        dw 8 dup(0)
stack ends
code segment
start:
        mov ax,data
        mov ds,ax
        mov ax,stack
        mov ss,ax
        mov sp,10h
        mov bx,0
        mov di,0
        mov ax,0b872h    ;算出屏幕第12行中间的显存的段起始位置放入ax中
        mov cx,3     ;外循环为3次，因为要显示三个字符串
s3:     push cx        ;三个进栈操作为外循环s3保存相关寄存器的值
        push ax        ;以防止它们的值在内循环中被破坏
        push di
        mov es,ax      ;此时es为屏幕第12行中间的显存的段起始位置
        mov si,0
        mov di,0
        mov cx,10h     ;内循环为10h次，因为一个字符串中含10h个字节
s1:     mov al,ds:[bx+si]
        mov es:[bx+di],al
        inc si
        add di,2
        loop s1      ;此循环实现偶地址中存放字符
        mov si,1   ;si的值设为1,从而为在显存奇地址中存放字符的颜色属性做准备
        pop di        ;将di的值恢复成进入内循环之前的时候的值
        mov al,ds:10h[bx+di]    ;取颜色属性[源OP寻址方式：相对基址变址]
        mov cx,10h     ;第二个内循环也为10h次
s2:     mov es:[bx+si],al
        add si,2
        loop s2       ;此循环实现奇地址中存放字符的颜色属性
        ;以下4句为下一趟外循环做准备
        inc di
        pop ax
        add ax,0ah   ;将显存的段起始地址设为当前行的下一行
                  ;[在段地址中加0ah,相当于在偏移地址中加了0a0h(=160d)]
        pop cx
        loop s3      
        mov ax,4c00h
        int 21h
code ends
end start

丝雨人

从第二张图可以看出  栈段把数据段覆盖了

vank

支持一个哦