实验10问题3数值显示

奥普瓯江

这个破问题可是坑哭我了，弄了很久很久，如有什么不对的地方还望指点一二，如果有什么更简单高效的书写方法也请不吝指教谢谢谢谢

1. assume cs:code, ds:data1, ds:data2, ds:data3
   
2. 
   
3. data1 segment
   
4.                 dw 123, 12666, 1, 8, 3, 38, 0
   
5. data1 ends
   
6. 
   
7. data2 segment
   
8.                 db 10 dup (0)
   
9. data2 ends
   
10. 
    
11. data3 segment
    
12.                 db 20 dup (0)
    
13. data3 ends
    
14. 
    
15. code segment
    
16. start:
    
17.                 mov di, 0
    
18.                 mov si, 0
    
19. one_str:
    
20.                 mov ax, data1
    
21.                 mov ds, ax
    
22.                 mov ax, word ptr ds:[si]
    
23.                 mov cx, ax
    
24.                 jcxz one_end
    
25.                 push si
    
26.                
    
27.                 mov si, 0
    
28.                 mov bx, data2
    
29.                 mov ds, bx
    
30.                 mov bx, data3
    
31.                 mov es, bx
    
32.                 call div_str
    
33.        
    
34.                 pop si
    
35.                 add si, 2
    
36.                 jmp short one_str
    
37. one_end:
    
38.                 mov dh, 8
    
39.                 mov dl, 3
    
40.                 mov cl, 2
    
41.                 call show_str
    
42.                
    
43.                 mov ax, 4C00H
    
44.                 int 21H
    
45.                
    
46. div_str:
    
47.                 mov dx, 0
    
48.                 mov bx, 10
    
49.                 div bx
    
50.                 add dl, 30H
    
51.                 mov byte ptr ds:[si], dl
    
52.                 mov cx, ax
    
53.                 jcxz div_end
    
54.                 inc si
    
55.                 jmp short div_str
    
56. div_end:
    
57.                 mov al, byte ptr ds:[si]
    
58.                 mov byte ptr es:[di], al
    
59.                 mov cx, si
    
60.                 inc di
    
61.                 jcxz chang_str
    
62.                 dec si
    
63.                 jmp short div_end
    
64. chang_str:
    
65.                 mov byte ptr es:[di], 20h
    
66.                 inc di
    
67.                 ret
    
68.                
    
69. show_str:
    
70.                 dec dh
    
71.                 mov ax, 0A0H
    
72.                 mul dh
    
73.                 mov bx, ax
    
74.                
    
75.                 mov ax, 2
    
76.                 mul dl
    
77.                 sub ax, 2
    
78.                
    
79.                 add bx, ax
    
80.                
    
81.                 mov ax, 0b800h
    
82.                 mov ds, ax
    
83.                 mov si, 0
    
84.                 mov di, 0
    
85.                 mov al, cl
    
86. ok:
    
87.                 mov cl, byte ptr es:[si]
    
88.                 mov ch, 0
    
89.                 jcxz good
    
90.                 mov byte ptr ds:[bx + di], cl
    
91.                 mov byte ptr ds:[bx + di + 1], al
    
92.                 inc si
    
93.                 add di, 2
    
94.                 jmp short ok
    
95. good:       
    
96.                 ret
    
97.                
    
98. code ends
    
99. end start

复制代码

以下为我按照我的理解所做的注释

1. assume cs:code, ds:data1, ds:data2, ds:data3
   
2. 
   
3. data1 segment
   
4.                 dw 123, 12666, 1, 8, 3, 38, 0
   
5. data1 ends
   
6. 
   
7. data2 segment
   
8.                 db 10 dup (0)
   
9. data2 ends
   
10. 
    
11. data3 segment
    
12.                 db 20 dup (0)
    
13. data3 ends
    
14. 
    
15. code segment
    
16. start:
    
17.                 mov di, 0                 ;初始化di寄存器为零
    
18.                 mov si, 0                 ;初始化si寄存器为零
    
19. one_str:
    
20.                 mov ax, data1             ;把data1数据段的段地址传给ax
    
21.                 mov ds, ax                ;把ax数据传给ds寄存器，使得数据段可以被调用
    
22.                 mov ax, word ptr ds:[si]  ;把data1中的两个字节的数据传给ax寄存器
    
23.                 mov cx, ax                ;把ax中数据传给cx已被jcxz验证
    
24.                 jcxz one_end              ;判断cx是否为零如果不为零不执行该条语句
    
25.                 push si                   ;使得si寄存器的数据进入栈中暂时保存，这里要注意栈的调用只能是两个字节也就是十六位数据不能是八位数据
    
26.                
    
27.                 mov si, 0                 ;再次初始化si，这里可以再次调用si是因为si以进栈，在循环重复的时候si将被pop从新赋值所以不影响si的使用
    
28.                 mov bx, data2             ;把data2数据段的段地址传给bx因为8086中只有ax和bx能被直接赋值，所以他俩需要交替使用，在这里ax以被使用所以就调用bx使他间接赋值给ds
    
29.                 mov ds, bx                ;把bx中的数据传给ds，因为这个循环是从one_str开始的所以从新付给ds数据并不冲突
    
30.                 mov bx, data3             ;把data3的值付给bx
    
31.                 mov es, bx                ;把bx数据传给es使得可以向data3数据段中读取写入数据
    
32.                 call div_str              ;跳转到div_str标记处
    
33.        
    
34.                 pop si                    ;把si的数值从栈中取回，并在此赋给si
    
35.                 add si, 2                 ;data1中的si加2
    
36.                 jmp short one_str         ;无条件跳转回one_str,该程序一共需要循环6次,因为data1中有六组word数据第七组是0
    
37. one_end:                          ;上面的循环执行完毕后跳转到该处向下执行上面数据转换和排序等执行完毕后，以下的数据就是显示数据
    
38.                 mov dh, 8                 ;把他显示在第八行         
    
39.                 mov dl, 3                 ;第三列这个地方
    
40.                 mov cl, 2                 ;显示是字体所呈现的属性，绿字
    
41.                 call show_str             ;跳转到字符标记处show_str:，当遇到ret这条语句就跳转回来，并继续向下执行
    
42.                
    
43.                 mov ax, 4C00H             ;结束语句
    
44.                 int 21H                   ;结束语句
    
45.                
    
46. div_str:                          ;16进制数转换成10进制的方法是用10除以16进制数每次的余数就是十进制数的一个元素，直到被除数为0结束
    
47.                 mov dx, 0                 ;初始dx寄存器数据，这里初始dx主要是为了div运算如果不初始化div运算就会报错
    
48.                 mov bx, 10                ;初始bx中的数据为10
    
49.                 div bx                    ;执行除法运算，被除数高位存放在dx中低位存放在了ax中，除数存放在了bx中，商存放在ax中余数存放在dx中
    
50.                 add dl, 30H               ;给余数加30h因为在ascii码中1的代码是31剩下的以此类推
    
51.                 mov byte ptr ds:[si], dl  ;把加30h后的余数传到data2中暂时储存
    
52.                 mov cx, ax                ;把被除数的数据传给cx
    
53.                 jcxz div_end              ;如果cx中的数据是0那么执行本条语句，跳转到div_end标记处，如果cx中的数据不是0那么什么也不做继续执行下一条语句
    
54.                 inc si                    ;使得si自动加1
    
55.                 jmp short div_str         ;无条件跳转到div_str标记处，jmp与jcxz是搭配使用的jcxz是他的结束条件
    
56. div_end:                          ;下列语句主要是把顺序倒了的数据调转过来并传到data3数据段
    
57.                 mov al, byte ptr ds:[si]  ;把data2中本次本次循环si这个字节传给al八位寄存器
    
58.                 mov byte ptr es:[di], al  ;al八位寄存器中的数据传给data3这个数据段偏移地址di这个位置
    
59.                 mov cx, si                ;把si中的数据传给cx
    
60.                 inc di                    ;di自动加1
    
61.                 jcxz chang_str            ;当cx中的数据为0的时候跳转到chang_str这个标记位置，如果cx中的数据不是0就什么也不做继续执行下一条语句
    
62.                 dec si                    ;si 自动减1
    
63.                 jmp short div_end         ;无条件跳转回div_end
    
64. chang_str:
    
65.                 mov byte ptr es:[di], 20h ;给米格段后面加上一个空格
    
66.                 inc di                    ;di自动加一
    
67.                 ret                       ;返回call div_str向下执行
    
68.                
    
69. show_str:
    
70.                 dec dh                    ;先让行数自动减一因为计算机是从0开始计算的，8行计算机计算的时候是从0开始的到7
    
71.                 mov ax, 0A0H              ;因为每一行是160个字节换算成16进制就是A0H，把被乘数赋给ax因为mul计算的时候是用ax乘一个寄存器或者内存单元
    
72.                 mul dh                    ;乘法运算，最后乘积保存在ax中
    
73.                 mov bx, ax                ;把ax传给bx暂时保存，因为我们还有第二个乘法需要使用到ax寄存器
    
74.                
    
75.                 mov ax, 2                 ;第二个乘法被乘数传给ax
    
76.                 mul dl                    ;乘法运算，乘积传给ax，3列每一列时2个字节一个字所以这里乘以2
    
77.                 sub ax, 2                 ;乘积减2这里的减2是因为计算机是从0开始运算的所以上面那三个列是从0开始的也就是0到2，这所说的列是一字为单位的不是以字节所以上面乘以2
    
78.                
    
79.                 add bx, ax                ;用行数字节数加上列数字节数最后定位到的就是我们要在屏幕那个地方输出，最后数据传输给bx
    
80.                
    
81.                 mov ax, 0b800h            ;把0B800H这个段地址传给ax
    
82.                 mov ds, ax                ;把ax中的数据传给ds使得他可以被读写
    
83.                 mov si, 0                 ;初始化si寄存器为零
    
84.                 mov di, 0                 ;初始化di寄存器为零
    
85.                 mov al, cl                ;把cl中字体的属性参数传给al因为我们下面要调用cl
    
86. ok:
    
87.                 mov cl, byte ptr es:[si]  ;把data3中si位置的数据传给cl中，这样可以及可以传输数据也可以有做下面的jcxz做判断是否跳转，因为汇编规定，内存段中不能相互传输数据，必须得借助寄存器
    
88.                 mov ch, 0                 ;初始化ch防止ch中有数据
    
89.                 jcxz good                 ;如果cx中数据是0及执行该条语句跳转到good标记处，如果不是0就不执行该语句
    
90.                 mov byte ptr ds:[bx + di], cl  ;把cl中的数据传给显示段地址0B800H偏移地址bx+di处
    
91.                 mov byte ptr ds:[bx + di + 1], al  ;把属性传给段地址0B800H偏移地址bx+di+1处
    
92.                 inc si                    ;si+1
    
93.                 add di, 2                 ;di+2因为显示段一次性是输入两个字节的数据所以di+2
    
94.                 jmp short ok              ;跳转回ok标记处继续执行输出
    
95. good:                                  ;如果jcxz good处检测到cx寄存器的数据是0就跳转到该处，并向下执行
    
96.                 ret                       ;返回call show_str处并向下执行结束语句
    
97.                
    
98. code ends
    
99. end start

复制代码

人造人

首先，这是你的代码运行的结果，有什么问题吗？


然后，我写了一个给你参考

1. assume cs:code, ds:data, ss:stack
   
2. data segment
   
3. data_arr        dw 123, 12666, 1, 8, 3, 38, 0
   
4. buffer                db 512 dup(0)
   
5. data ends
   
6. stack segment
   
7.         db 512 dup(0)
   
8. stack ends
   
9. code segment
   
10. ; void NumberToString(uint16_t number, char *buffer);
    
11. NumberToString:
    
12.         push        bp
    
13.         mov        bp, sp
    
14.         push        bx
    
15.         push        si
    
16.         push        di
    
17.        
    
18.         mov        di, [bp + 6]        ; buffer
    
19.         mov        ax, [bp + 4]        ; number
    
20.         xor        dx, dx
    
21.         mov        cx, 10
    
22. @@:
    
23.         div        cx
    
24.         add        dx, '0'
    
25.         mov        [di], dl
    
26.         inc        di
    
27.         xor        dx, dx
    
28.         cmp        ax, 0
    
29.         jne        @B
    
30.         mov        byte ptr [di], 0        ; '\0'
    
31.        
    
32.         ; 下面翻转字符串
    
33.         dec        di
    
34.         mov        si, [bp + 6]        ; buffer
    
35. @@:
    
36.         cmp        si, di
    
37.         jge        @F
    
38.         mov        ah, [si]
    
39.         mov        al, [di]
    
40.         mov        [si], al
    
41.         mov        [di], ah
    
42.         inc        si
    
43.         dec        di
    
44.         jmp        @B
    
45. @@:
    
46.         pop        di
    
47.         pop        si
    
48.         pop        bx
    
49.         mov        sp, bp
    
50.         pop        bp
    
51.         ret
    
52. 
    
53. ; void ShowString(uint8_t x, uint8_t y, char *str, uint8_t attr);
    
54. ShowString:
    
55.         push        bp
    
56.         mov        bp, sp
    
57.         push        bx
    
58.         push        si
    
59.         push        di
    
60.         push        es
    
61.        
    
62.         mov        ax, 0b800h
    
63.         mov        es, ax
    
64.         mov        dl, [bp + 6]        ; y
    
65.         mov        al, 160
    
66.         mul        dl
    
67.         mov        di, ax
    
68.         mov        dl, [bp + 4]        ; x
    
69.         mov        al, 2
    
70.         mul        dl
    
71.         add        di, ax
    
72.        
    
73.         mov        ah, [bp + 10]        ; attr
    
74.         mov        si, [bp + 8]        ; str
    
75. @@:
    
76.         mov        al, [si]
    
77.         cmp        al, 0
    
78.         je        @F
    
79.         mov        es:[di], ax
    
80.         inc        si
    
81.         add        di, 2
    
82.         jmp        @B
    
83. @@:
    
84.         pop        es
    
85.         pop        di
    
86.         pop        si
    
87.         pop        bx
    
88.         mov        sp, bp
    
89.         pop        bp
    
90.         ret
    
91. 
    
92. start:
    
93.         mov        ax, stack
    
94.         mov        ss, ax
    
95.         mov        sp, 512
    
96.         mov        ax, data
    
97.         mov        ds, ax
    
98.        
    
99.         mov        si, offset data_arr
    
100.         xor        bx, bx
     
101. @@:
     
102.         cmp        word ptr [si], 0
     
103.         je        @F
     
104.         mov        ax, offset buffer
     
105.         push        ax
     
106.         push        [si]
     
107.         call        NumberToString
     
108.         add        sp, 4
     
109.        
     
110.         mov        ax, 07h
     
111.         push        ax
     
112.         mov        ax, offset buffer
     
113.         push        ax
     
114.         push        bx
     
115.         mov        ax, 0
     
116.         push        ax
     
117.         call        ShowString
     
118.         add        sp, 8
     
119.        
     
120.         add        si, 2
     
121.         inc        bx
     
122.         jmp        @B
     
123. @@:
     
124.         mov        ax, 4c00h
     
125.         int        21h
     
126. code ends
     
127. end start
     

复制代码

人造人

上面的对齐有问题，我这边是对齐的

人造人

main.zip (812 Bytes, 下载次数: 1)

2018-11-17 22:20 上传

点击文件名下载附件

奥普瓯江

人造人 发表于 2018-11-17 22:17
首先，这是你的代码运行的结果，有什么问题吗？

谢谢，我研究研究吧因为你给的那个程序有好的语句我还没有学到比如说cmp、jmp @B、xor、je等这些我都还不会，所以你这个程序我也是看的一知半解没全看懂，我先往下学也许以后会看懂的

人造人

奥普瓯江 发表于 2018-11-18 10:54
谢谢，我研究研究吧因为你给的那个程序有好的语句我还没有学到比如说cmp、jmp @B、xor、je等这些我都还不 ...

嗯