【老刘谈算法003】命令行参数的处理和获取——ArgCl函数实现分析

OldLiu

在非汇编语言中，处理并分割命令行参数（CmdLine）一般是由编译器在可执行文件中预置处理代码或者调用运行时库完成，
而在汇编中，我们需要手动调用Windows的API——GetCommandLine函数来获得一份杂乱的字符串（包含了可执行文件路径以及命令行参数），
还好在MASM32Library中，汇编爱好者们提供了一个取得命令行参数的函数，省去了我们亲自造轮子的功夫，
对于各种不按套路出牌的CmdLine，该函数将如何处理?这激起了我分析这段代码的兴趣。
当然，下面所列举的算法及出现特殊情况时的处置办法，可能与其他语言的处理方式不同，仅供参考。
算法流程如下（流程图绘制有bug，所以下面的一些文字可能有些怪异）：

                               
登录/注册后可看大图

代码如下：

1. 
   
2. ;原出处：MASM32 SDK
   
3. ;注释修改&中文注释添加 By 老刘
   
4. 
   
5. ; #########################################################################
   
6. ;
   
7. ;            这个程序是在Iczelion和Lucifer的技术支持下开发出来的。
   
8. ;
   
9. ; #########################################################################
   
10. 
    
11.       .386
    
12.       .model flat, stdcall  ; 32 bit memory model
    
13.       option casemap :none  ; case sensitive
    
14. 
    
15.       include \MASM32\INCLUDE\kernel32.inc
    
16. 
    
17.   ; ------------------------------------
    
18.   ; 请读文本最后的用法
    
19.   ; ------------------------------------
    
20. 
    
21.     ArgCl PROTO :DWORD,:DWORD
    
22. 
    
23.     .code
    
24. 
    
25. ; #########################################################################
    
26. 
    
27. ArgCl proc ArgNum:DWORD, ItemBuffer:DWORD
    
28. 
    
29.     LOCAL cmdLine        :DWORD
    
30.     LOCAL cmdBuffer[192] :BYTE
    
31.     LOCAL tmpBuffer[192] :BYTE
    
32. 
    
33.   ; --------------
    
34.   ; 储存 esi & edi
    
35.   ; --------------
    
36.     push esi
    
37.     push edi
    
38. 
    
39.     invoke GetCommandLine
    
40.     mov cmdLine, eax        ; address command line
    
41. 
    
42.     cmp ArgNum, 0
    
43.     jne @F
    
44.     xor eax, eax
    
45.       jmp jmp_In
    
46.     @@:
    
47. 
    
48.     mov esi, cmdLine
    
49.     lodsb                   ;al=byte ptr [esi]
    
50.     cmp al, 34
    
51.     je @F                   ;如果不是半角双引号，退出
    
52.       pop edi
    
53.       pop esi
    
54.       xor eax, eax          ; eax=0
    
55.       ret
    
56.     @@:
    
57.    
    
58.   ; -------------------------------------------------
    
59.   ; 统计引号标记来确认其是否双双匹配
    
60.   ; -------------------------------------------------
    
61.     xor ecx, ecx            ; 将ecx作为引号个数的计数器
    
62.     mov esi, cmdLine
    
63.    
    
64.     @@:
    
65.       lodsb
    
66.       cmp al, 0                                ;到达末尾
    
67.       je @F
    
68.       cmp al, 34            
    
69.       jne @B                                        ;不为引号则继续循环
    
70.       inc ecx                               ;ecx+=1
    
71.       jmp @B
    
72.     @@:
    
73. 
    
74.     push ecx                ;储存计数的值
    
75. 
    
76.     shr ecx, 1
    
77.     shl ecx, 1              ;ecx-=ecx%2
    
78. 
    
79.     pop eax                 ;eax=计数的值
    
80.     cmp eax, ecx
    
81.     je @F                                        ;引号数量为偶数（匹配）则下跳
    
82.       pop edi
    
83.       pop esi
    
84.       mov eax, 3            ;返回3
    
85.       ret
    
86.     @@:
    
87. 
    
88.   ; -------------------------------------------
    
89.   ; 下面的代码移除（程序的）路径及文件名
    
90.   ; cmdline只留下参数
    
91.   ; -------------------------------------------
    
92.     mov esi, cmdLine                ;esi=cmdline指针
    
93.     lea edi, tmpBuffer                ;edi=tmpBuffer指针
    
94.    
    
95.     lodsb           ;读第一个引号
    
96. 
    
97.     @@:                                ;去除字符直到读到第二个引号
    
98.       lodsb
    
99.       cmp al, 34
    
100.       jne @B
     
101.       
     
102.     wtIn:
     
103.       lodsb
     
104.       cmp al, 0
     
105.       je wtOut
     
106.       stosb         ;转移到tmpBuffer
     
107.       jmp wtIn
     
108.     wtOut:
     
109.       stosb         ;tmpBuffer结尾
     
110. 
     
111.   ; -----------------------------------
     
112.   ; 处理空参数""（其实就是""->255）
     
113.   ; -----------------------------------
     
114. 
     
115.     lea esi, tmpBuffer
     
116.     lea edi, cmdBuffer
     
117. 
     
118.     xor edx, edx    ;清0，作为标志寄存器使用
     
119. 
     
120.     rnsSt:
     
121.       lodsb
     
122.       cmp al, 0       
     
123.       je rnsEnd                ;esi指向null，即处理完毕
     
124. 
     
125.       .if al != 34                        ;该字符不为引号
     
126.         .if edx == 1                ;前一字符为引号
     
127.           xor edx, edx        ;edx=0
     
128.           jmp rnsWrt
     
129.         .endif
     
130.       .elseif al == 34        ;该字符为引号
     
131.         .if edx == 1                ;前一字符为引号
     
132.           mov al, 255
     
133.           stosb                                ;edi指向地址=255，edi++，其实就是引号换255
     
134.           mov al, 34                ;再写入一个引号
     
135.           stosb
     
136.           dec edx                        ;edx=0
     
137.           jmp rnsSt
     
138.         .elseif edx == 0
     
139.           inc edx                        ;标记
     
140.         .endif
     
141.       .endif
     
142. 
     
143.     rnsWrt:
     
144.       stosb
     
145.       jmp rnsSt
     
146. 
     
147.     rnsEnd:
     
148.       stosb                ;cmdBuffer结尾
     
149. 
     
150.   ; ----------------------------------
     
151.   ; 替换有引号包裹的空格（引号中的空格->254）
     
152.   ; 删除引号（上面""换成的255不会被删除）
     
153.   ; ----------------------------------
     
154.     lea esi, cmdBuffer                ;下面操作的是同一个地址，但由于先读后写，并不冲突。
     
155.     lea edi, cmdBuffer
     
156. 
     
157.     subSt:
     
158.       lodsb
     
159.       cmp al, 0
     
160.       jne @F
     
161.       jmp subOut                ;完成
     
162.     @@:
     
163.       cmp al, 34
     
164.       jne subNxt
     
165.       jmp subSl                        ;如果有引号，进入子循环
     
166.     subNxt:
     
167.       stosb                                ;写回去
     
168.       jmp subSt
     
169.     ; --------------------------
     
170.     subSl:
     
171.       lodsb
     
172.       cmp al, 32    ;是空格
     
173.       jne @F
     
174.         mov al, 254 ;空格换254
     
175.       @@:
     
176.       cmp al, 34
     
177.       jne @F
     
178.         jmp subSt        ;子循环完毕，返回
     
179.       @@:
     
180.       stosb                                ;写回去
     
181.       jmp subSl
     
182.     ; --------------------------
     
183.     subOut:
     
184.       stosb         ;结尾
     
185. 
     
186.     ; ------------------------
     
187.     ;Tab-->空格
     
188.     ; ------------------------
     
189. 
     
190.     lea esi, cmdBuffer
     
191.     lea edi, cmdBuffer
     
192. 
     
193.     @@:
     
194.       lodsb
     
195.       cmp al, 0
     
196.       je rtOut
     
197.       cmp al, 9
     
198.       jne rtIn                        ;不为Tab跳
     
199.       mov al, 32                ;9-->32
     
200.     rtIn:
     
201.       stosb
     
202.       jmp @B
     
203.     rtOut:
     
204.       stosb
     
205. 
     
206.   ; ----------------------------------------------------
     
207.   ; 下面的代码分割正确的arg，
     
208.   ; 并且将arg写入目的地址
     
209.   ; ----------------------------------------------------
     
210.     lea eax, cmdBuffer
     
211.     mov esi, eax
     
212.     mov edi, ItemBuffer ; 目标地址
     
213. 
     
214.     mov ecx, 1          ; 做计数器
     
215. 
     
216.   ; ---------------------------
     
217.   ; 去掉先导空格（如果有的话）
     
218.   ; ---------------------------
     
219.     @@:
     
220.       lodsb
     
221.       cmp al, 32
     
222.       je @B
     
223. 
     
224.     l2St:
     
225.       cmp ecx, ArgNum     ; 传入的ArgNum
     
226.       je clSubLp2                                ;到达需要取参的位置
     
227.       lodsb
     
228.       cmp al, 0
     
229.       je cl2Out
     
230.       cmp al, 32
     
231.       jne cl2Ovr           ; if not space
     
232. 
     
233.     @@:
     
234.       lodsb
     
235.       cmp al, 32          ; 捕捉连续的空格
     
236.       je @B
     
237. 
     
238.       inc ecx             ;arg计数器++
     
239.       cmp al, 0
     
240.       je cl2Out
     
241. 
     
242.     cl2Ovr:
     
243.       jmp l2St
     
244. 
     
245.     clSubLp2:
     
246.       stosb                                ;参数第一个字符写进去
     
247.     @@:
     
248.       lodsb
     
249.       cmp al, 32
     
250.       je cl2Out
     
251.       cmp al, 0
     
252.       je cl2Out
     
253.       stosb
     
254.       jmp @B
     
255. 
     
256.     cl2Out:
     
257.       mov al, 0
     
258.       stosb
     
259. 
     
260.   ; ---------------------------------
     
261.   ; 空格换回去
     
262.   ; ---------------------------------
     
263.     mov esi, ItemBuffer
     
264.     mov edi, ItemBuffer
     
265. 
     
266.     @@:
     
267.       lodsb
     
268.       cmp al, 0
     
269.       je @F
     
270.       cmp al, 254
     
271.       jne nxt1
     
272.       mov al, 32
     
273.     nxt1:
     
274.       stosb
     
275.       jmp @B
     
276.     @@:
     
277. 
     
278.   ; -------------------------------------------------
     
279.   ; 替换“”为0
     
280.   ; -------------------------------------------------
     
281.     mov esi, ItemBuffer
     
282.     mov edi, ItemBuffer
     
283.     lodsb
     
284.     cmp al, 255 ;见108+行
     
285.     jne @F
     
286.     mov al, 0   ;替换为0
     
287.     stosb
     
288.     mov eax, 4  ;返回4
     
289.     pop edi
     
290.     pop esi
     
291.     ret
     
292.   @@:
     
293. 
     
294.   ; ----------------------------------
     
295.   ; 如果参数数量不够，
     
296.   ; ItemBuffer首位设0
     
297.   ; ----------------------------------
     
298. 
     
299.     .if ecx < ArgNum
     
300.     jmp_In:
     
301.       mov edi, ItemBuffer
     
302.       mov al, 0
     
303.       stosb                        ;mov byte ptr [edi],al
     
304.       mov eax, 2  ;返回值为2说明参数数量不够或ArgNum为0
     
305.       jmp @F
     
306.     .endif
     
307. 
     
308.     mov eax, 1  ;cmdline成功处理
     
309. 
     
310.     @@:
     
311. 
     
312.       pop edi
     
313.       pop esi
     
314. 
     
315.     ret
     
316. 
     
317. ArgCl endp
     
318. 
     
319. ; #########################################################################
     
320. ;
     
321. ;      这个子程序接收2个参数
     
322. ;
     
323. ;       1.  你要获取的命令行参数的序号。
     
324. ;       2.  结果的缓存区地址。
     
325. ;      
     
326. ;       Example: 如果有4个参数放置于CmdLine中，
     
327. ;       如progname arg1 arg2 arg3 arg4 , 使用如下手段调用该函数,
     
328. ;
     
329. ;       invoke ArgCl,3,ADDR buffer
     
330. ;
     
331. ;       将会将arg3放入buffer。
     
332. ;
     
333. ;       注意，引用的Arg支持长文件名。
     
334. ;
     
335. ;       确保缓存区的大小足够接收参数，
     
336. ;       cmdline最大只能有128字节长（现在为32kb(非CMD中传参)，该代码的编写日期为1999年），
     
337. ;       在一个函数中，使用
     
338. ;
     
339. ;       LOCAL Buffer[128]:BYTE
     
340. ;
     
341. ;       eax中的返回值
     
342. ;
     
343. ;       0 = GetCommandLine返回Null
     
344. ;       1 = cmdline成功处理
     
345. ;       2 = 已经尝试处理，但是参数数量不够或ArgNum为0
     
346. ;       3 = 引号数目不匹配（不为偶数）
     
347. ;       4 = 空的引号标记（类似""）
     
348. ;
     
349. ;       Tab和空格都为界定字符
     
350. ;
     
351. ; #########################################################################
     
352. 
     
353. end
     

复制代码

## 漏洞分析 ##
当有效参数长度>128时，或当PE文件路径后面的参数长>192时，会发生溢出bug。
当传入参数的字符串内部出现半角双引号时（如        arg""arg），会触发"空引号标记"未换回BUG，原因为Line280~Line291作者只判断了第一个字符是否被标记为"空引号标记"。

作者的脑洞还是不够大啊（笑）