《汇编语言》实验七

_________

assum  cs:code

data segment  
    dw '1975','1976','1977','1978','1979','1980','1981','1982','1983'
        dw '1984','1985','1986','1987','1988','1989','1990','1991','1992'
    dw '1993','1994','1995'   
   
        dd 16,22,382,1356,2390,8000,16000,24486,50065,97479,140417,197514  
        dd 345980,590827,803530,1183000,1843000,2759000,3753000,4649000,5937000  
       
        dw 3,7,9,13,28,38,130,220,476,778,1001,1442,2258,2793,4037,5635,8226  
        dw 11542,14430,15257,17800
data ends   

table segment  
    db 21 dup ('year summ ne ?? ')  
table ends   

code segment  
start:mov ax,data
      mov ds,ax
          mov ax,table
          mov es,ax
          mov si,0
          mov di,0
          mov cx,21
   s: mov ax,[si+0]
      mov es,[dx+si+0],ax
          mov ax,[di+84]
          mov bx,[di+86]
          mov es[dx+di+5],ax
          mov es[bx+di+7],bx
          mov ax,[si+168]
          mov es[dx+di+10],ax
          mov ax,[di+84]
          mov bx,[di+86]
          div word ptr ds:[si+168]
          mov es[dx+13],ax
          add dx,16
          add si,2
          add di4
          loop s
     
          mov ax,4c00h
      int 21h
code ends
end start

求高手指点

ROY

start:mov ax,data
      mov ds,ax
          mov ax,table
          mov es,ax
          mov si,0
          mov di,0                   下面有两个寄存器没有初始化就用上了DX，BX
          mov cx,21
   s: mov ax,[si+0]
      mov es,[dx+si+0]                         这里是四个字节的字符串，你只操作了一个word
          mov ax,[di+84]
          mov bx,[di+86]
          mov es[dx+di+5],ax
          mov es[bx+di+7],bx
          mov ax,[si+168]
          mov es[dx+di+10],ax            这里loop有问题。
          mov ax,[di+84]
          mov bx,[di+86]                这里是把ds:[di+86]的值给DX
          div word ptr ds:[si+168]
          mov es[dx+13],ax
          add dx,16
          add si,2
          add di4                          笔误吧？

                       逻辑有很大的问题，自己debug一下。
          loop s

没个正样

朋友你好！
你这一题的错误不少啊！有的是理念问题，有的是基础问题。
比如说：在div除法指令中，被除数默认是放在ax或ax和dx中的；当数据比较大，达到32位时，其高16位默认放在dx中，低16位默认放在ax中，商放在ax中，余数放在dx中的。
可是，你在本题中放在哪里呢！
          mov ax,[di+84]
          mov bx,[di+86]
          div word ptr ds:[si+168]
          mov es[dx+13],ax
你是错误地把高16位默认放在bx中！
也就是说：你随意的运用了寄存器。我个人认为你的这种习惯不太好，这样一来容易出错，二来别人很难跟你形成默契，因而产生不了团队中的合力。
当然了，这个世上大多数事情都不是绝对的。太过于墨守成规，则束缚了自己；太过于自由散漫，则成不了大器。关键要把握好这个度。


下面是我的，如果你弄懂了就过，不要在某一题上花费太多的时间和精力。

assume cs:code,ds:data,es:table

data segment
     db '1975','1976','1977','1978','1979','1980','1981','1982','1983'
     db '1984','1985','1986','1987','1988','1989','1990','1991','1992'
     db '1993','1994','1995'                                    ;以上是表示21年的21个字符串。
     dd 16,22,382,1356,2390,8000,16000,24486,50065,97479,140417,197514
     dd 345980,590827,803530,1183000,1843000,2759000,3753000,4649000,5937000
     ;以上是表示21年公司总收的21个dword型数据
     dw 3,7,9,13,28,38,130,220,476,778,1001,1442,2258,2793,4037,5635,8226
     dw 11542,14430,45257,17800
     ;以上是表示21年公司雇员人数的21个word型数据
data ends

table segment
      db 21 dup('year summ ne ?? ')            ;以上是表格。
table ends

code segment
start:mov ax,data
   mov ds,ax
   mov ax,table
   mov es,ax
   
   mov bx,0
   mov si,0
   mov di,0
   
   mov cx,21
s:mov al,[bx]
   mov es:[di],al
   mov al,[bx+1]
   mov es:[di+1],al
   mov al,[bx+2]
   mov es:[di+2],al
   mov al,[bx+3]
   mov es:[di+3],al
   ;以上8句的作用是存放年份
   mov ax,54h[bx]     ;第一个'年收入'的段基址为54H
   mov dx,56h[bx]
   mov es:5h[di],ax
   mov es:7h[di],dx
      ;以上4句的作用是存放公司总收人。
   mov ax,0A8h[si]    ;第一个'人数'的段基址为0A8H
   mov es:0Ah[di],ax
   ;以上2句是存放公司的人数
    mov ax,54h[bx]
    mov dx,56h[bx]
    div word ptr ds:0A8h[si]
    mov es:0dh[di],ax  
        ;以上3句是存放人均收入
    add bx,4
    add si,2
    add di,16
;以上3句是为下一次循环时存放数据做准备
;3个寄存器递增的速度决定了所要存取的数据的位置的偏移地址
    loop s  ;跳到标号s处
    mov ax,4c00h
    int 21h

code ends
end start