[已解决]汇编 寻址方式在结构化数据访问中的应用

MakoMori

题目为分别21个年份 人数 收入 那题
在最后 add bx,4
            add si,2
            add di,16
问题: di,16可以理解在16位中因为要人为换行，这个没问题
问题是 前面的 bx si 为什么还要加4 2？
不应该直接在新的行数重复 0 1 2 3 存放年份就好了吗？ 求解

最佳答案

月排行榜 / 总排行榜

newu

2019-6-27 15:46:17

MakoMori 发表于 2019-6-26 23:36
好了，求解，麻烦了，可以的话加个Q联系，初学很多都不太懂

db 21 dup ('year summ ne ?? ')，dup这个伪指令是把引号这里面的16个字节重复21遍，所以是add di, 16

add bx,4
add si,2
这两句在你的汇编代码中都已经说的很清楚了，就是用来存放偏移的，以便下一次循环读下一组数

mov bx,0 ;bx存放 年份和收入的偏移指针(由于年份和收入每年都是占4字节，所以可以用同一个偏移指针)
mov si,0 ;si存放 人数偏移指针，每年增加2字节
mov di,0 ;di存放 table段中偏移指针，每年增加16字节

跳转到最佳答案楼层

jackz007

楼主应该贴出完整代码再提出问题。

暗pluto

没有具体题目吗？

newu

说的再详细点吧，最好有代码，因为很多人都忘记了

MakoMori

assume cs:code,ds:data,es:table
data segment
db '1975','1976','1977','1978','1979','1980','1981','1982','1983'  ;年份数据，每年占4字节
db '1984','1985','1986','1987','1988','1989','1990','1991','1992'
db '1993','1994','1995'
dd 16,22,382,1356,2390,8000,16000,24486,50065,97479,140417,197514  ;收入数据，每年占4字节
dd 345980,590827,803530,1183000,1843000,2759000,3753000,4649000,5937000
dw 3,7,9,13,28,38,130,220,476,778,1001,1442,2258,2793,4037,5635,8226 ;人数数据，每年占2字节
dw 11452,14430,15257,17800
data ends
table segment
db 21 dup ('year summ ne ?? ')
table ends
code segment
start:

mov ax,data
mov ds,ax ;ds放data数据
mov ax,table
mov es,ax ;es放table数据

mov bx,0 ;bx存放 年份和收入的偏移指针(由于年份和收入每年都是占4字节，所以可以用同一个偏移指针)
mov si,0 ;si存放 人数偏移指针，每年增加2字节
mov di,0 ;di存放 table段中偏移指针，每年增加16字节

mov cx,21 ;循环21年
s:
;开始处理年份
mov ax,ds:[bx] ;bx处年份的前2个字节
mov es:[di],ax ;把2个字节写入table中
mov ax,ds:[bx+2];把后2个字节放入ax
mov es:[di+2],ax;写入table

;开始处理收入
mov ax,ds:84[bx];每一年份的年份数据和收入数据相差84字节
mov es:[di+5],ax;写入字节
mov dx,ds:86[bx];放在高位中
mov es:[di+7],dx

;先做除法，填写好平均工资，省去保存的麻烦
div word ptr ds:168[si] ;dxax除以168[si]表示的人数
mov es:[di+13],ax ;ax中存的商值放入每行13位置处

;开始处理人数
mov ax,ds:168[si]
mov es:[di+10],ax

add bx,4 ;bx每年加4个字节
add si,2 ;si每年加2个字节
add di,16 ;di每年加16个字节

loop s

mov ax,4c00H
int 21H
code ends
end start

MakoMori

newu 发表于 2019-6-26 20:00
说的再详细点吧，最好有代码，因为很多人都忘记了

好了，在最后求解，麻烦了

MakoMori

暗pluto 发表于 2019-6-26 16:19
没有具体题目吗？

好了，求解谢谢了

MakoMori

jackz007 发表于 2019-6-26 16:15
楼主应该贴出完整代码再提出问题。

好了，求解，麻烦了，可以的话加个Q联系，初学很多都不太懂

newu

MakoMori 发表于 2019-6-26 23:36
好了，求解，麻烦了，可以的话加个Q联系，初学很多都不太懂

db 21 dup ('year summ ne ?? ')，dup这个伪指令是把引号这里面的16个字节重复21遍，所以是add di, 16

add bx,4
add si,2
这两句在你的汇编代码中都已经说的很清楚了，就是用来存放偏移的，以便下一次循环读下一组数

mov bx,0 ;bx存放 年份和收入的偏移指针(由于年份和收入每年都是占4字节，所以可以用同一个偏移指针)
mov si,0 ;si存放 人数偏移指针，每年增加2字节
mov di,0 ;di存放 table段中偏移指针，每年增加16字节