[已解决]Win32匯編窗口句柄問題

kikiatw

Win32匯編中, 第一個窗口程序有些小問題想請教一下
1. GetModuleHandle 獲取當前的執行檔的句柄, 這個是因為這個執行檔載入記憶體後, 需要一個辨識, 所以才有這個句柄我可以理解,
可是為什麼要把這個句柄當作參數送到WndClassEx中? 是因為WndClassEx需要一個父程序的句柄當作辨識, 辨識這個WndClassEx是屬於哪一個程序的嗎?

2. CreateWindowEx創建一個窗口的時候, 我們要給他一個句柄, 這個句柄我們也是給他hInstance, 與註冊WndClassEx的句柄是一樣的,
是因為這個窗口也需要一個父程序的句柄當作辨識, 辨識這個窗口是屬於哪一個程序的嗎?

最佳答案

月排行榜 / 总排行榜

人造人

2019-11-2 16:13:18

是不是明白了？这就是hInstance
hInstance 保存着当前exe文件的地址

跳转到最佳答案楼层

人造人

如果能附上一个简短的程序辅以说明，那就更好了

kikiatw

;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; 窗口程序的模板代碼
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
                .386
                .model flat,stdcall
                option casemap:none
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; Include 文件定義
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
include                windows.inc
include                gdi32.inc
includelib        gdi32.lib
include                user32.inc
includelib        user32.lib
include                kernel32.inc
includelib        kernel32.lib
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; 數據段
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
                .data?
hInstance        dd        ?
hWinMain        dd        ?
hWinSlav        dd        ?

                .const
szClassName        db        'MyClass',0
szCaptionMain        db        'My first Window !',0
szText                db        'Welcome to fishc.com!',0
szButton        db        'button',0
szButtonText        db        '&OK',0
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; 代碼段
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
                .code
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; 窗口過程
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
_ProcWinMain        proc        uses ebx edi esi hWnd,uMsg,wParam,lParam
                local        @stPs:PAINTSTRUCT
                local        @stRect:RECT
                local        @hDc

                mov        eax,uMsg
;********************************************************************
                .if        eax ==        WM_PAINT
                        invoke        BeginPaint,hWnd,addr @stPs
                        mov        @hDc,eax

                        invoke        GetClientRect,hWnd,addr @stRect
                        invoke        DrawText, @hDc, addr szText, -1, addr @stRect, DT_SINGLELINE or DT_CENTER or DT_VCENTER
                        invoke        EndPaint,hWnd,addr @stPs
;********************************************************************
                .elseif        eax ==        WM_CLOSE
                        invoke        DestroyWindow,hWinMain
                        invoke        DestroyWindow,hWinSlav
                        invoke        PostQuitMessage,NULL
;********************************************************************
                .else
                        invoke        DefWindowProc,hWnd,uMsg,wParam,lParam
                        ret
                .endif
;********************************************************************
                xor        eax,eax
                ret
_ProcWinMain        endp

;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
;********************************************************************
; 註冊窗口類
;********************************************************************
_WinMain        proc
                local        @stWndClass:WNDCLASSEX
                local        @stMsg:MSG

                invoke        RtlZeroMemory,addr @stWndClass,sizeof @stWndClass
;********************************************************************
; 註冊窗口類
;********************************************************************
                invoke        GetModuleHandle,NULL
                mov        hInstance,eax
                mov        @stWndClass.hInstance,eax
;                push        hInstance
;                pop        @stWndClass.hInstance
                invoke        LoadCursor,0,IDC_ARROW
                mov        @stWndClass.hCursor,eax
                mov        @stWndClass.cbSize,sizeof WNDCLASSEX
                mov        @stWndClass.style,CS_HREDRAW or CS_VREDRAW
                mov        @stWndClass.lpfnWndProc,offset _ProcWinMain
                mov        @stWndClass.hbrBackground,COLOR_WINDOW+1
                mov        @stWndClass.lpszClassName,offset szClassName
                invoke        RegisterClassEx,addr @stWndClass
;********************************************************************
; 建立並顯示窗口
;********************************************************************
                invoke        CreateWindowEx,WS_EX_CLIENTEDGE, offset szClassName, offset szCaptionMain, WS_OVERLAPPEDWINDOW, 100,100,600,400, NULL, NULL, hInstance, NULL
                mov        hWinMain,eax
                invoke        ShowWindow,hWinMain,SW_SHOWNORMAL
                invoke        UpdateWindow,hWinMain

                invoke        CreateWindowEx,WS_EX_CLIENTEDGE, offset szButton, offset szButtonText, WS_CHILD or WS_VISIBLE, 10,10,100,80, hWinMain, 1, hInstance, NULL
                mov        hWinSlav,eax
                invoke        ShowWindow,hWinSlav,SW_SHOWNORMAL
                invoke        UpdateWindow,hWinSlav

;********************************************************************
; 消息循環
;********************************************************************
                .while        TRUE
                        invoke        GetMessage,addr @stMsg,NULL,0,0
                        .break        .if eax        == 0
                        invoke        TranslateMessage,addr @stMsg
                        invoke        DispatchMessage,addr @stMsg
                .endw
                ret

_WinMain        endp
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
start:
                call        _WinMain
                invoke        ExitProcess,NULL
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
                end        start

以上是一個簡短的程序, 麻煩您了

執行後

kikiatw

     invoke        CreateWindowEx,WS_EX_CLIENTEDGE, offset szButton, offset szButtonText, WS_CHILD or WS_VISIBLE, 10,10,100,80, hWinMain, 1, hInstance, NULL
                mov        hWinSlav,eax
                invoke        ShowWindow,hWinSlav,SW_SHOWNORMAL
                invoke        UpdateWindow,hWinSlav

我自己照著書本多呼叫了一個按鈕, 然後看書上的說明, hWinMain 就是這個按鈕的父窗口, hInstance 就應該就是firstwindow的模塊, 規定就是這樣傳入, 所以第二個問題我沒問題了, 所以回來看第一個問題, 模塊, 就是這個程序載入內存的一個區域, hInstance 就是這個程序載入的標示符, 這個模塊可以看到自己的4GB內存
書上說WndClassEx.hInstance 就是: "指定要註冊的窗口類(WndClassEx)屬於哪個模塊 "
從上面這段話看起來, 也就是說, 只要理解模塊其實就是一個程序執行檔(firstwindow.exe)載入記憶體後, 系統會分配一個號碼給這個被執行的程序(firstwindow.exe), 也就是這個模塊的代碼, 如果是這樣理解的話, 我第一個問題似乎也算是解了, 對吧?

人造人

是不是明白了？这就是hInstance
hInstance 保存着当前exe文件的地址

kikiatw

哈哈哈哈, 看到MZ開頭跟這個位址, 雖然還沒學到PE結構, 但是我完全明白, 終於了解了, 所以我之前的理解是對的, 感謝!!

〃忝書γě渎ぐ

人造人 发表于 2019-11-2 14:13
如果能附上一个简短的程序辅以说明，那就更好了

你好，能不能帮忙看看这个问题，https://fishc.com.cn/thread-152138-1-1.html