王爽汇编实验16的问题弄不懂啊

Μiss＾依然

搞不明白啊怎么回事下面的CALL WORD PTR TABLE[BX]运行起来和CS不一样啊。解决方法我只会用OFFSET了那学这表有毛用啊
求高手前辈们指教啊
assume cs:code
code segment
start: mov ax,0
mov es,ax
mov ax,cs
mov ds,ax
cli
mov word ptr es:[7ch*4],200h
mov word ptr es:[7ch*4+2],0
sti
mov si,offset sj
mov di,200h
mov cx,offset sjends-offset sj
cld
rep movsb
mov ax,0
mov ah,2
int 7ch
mov ax,4c00h
int 21h
org 200h
sj:jmp short rukou
table dw sub0,sub1,sub2,sub3
rukou:
cmp ah,3
ja ko
push bx
mov bx,0
mov bh,ah
add bx,bx
call word ptr table[bx]（其它的先不管主要是这句的问题，郁闷了table[bx]怎么就跳到206去了。。。按理说u应该啊，按我的理解应该跳到SUB2的偏移地址里面去啊）
pop bx
ko: iret
sub0: push es
push di
push cx
push bx
mov bx,0b800h
mov es,bx
mov bh,' '
mov di,0
mov cx,2000
sub0s: mov byte ptr es:[di],bh
add di,2
loop sub0s
pop bx
pop cx
pop di
pop es
ret
sub1: push ax
push es
push di
push cx
mov ax,0b800h
mov es,ax
mov cx,2000
mov di,1
sub1s: and byte ptr es:[di],00000000b
or byte ptr es:[di],00000111b
add di,2
loop sub1s
pop cx
pop di
pop es
pop ax
ret
sub2:
push ax
push es
push di
push cx
mov ax,0b800h
mov es,ax
mov cx,2000
mov di,1
sub2s: and byte ptr es:[di],00000000b
or byte ptr es:[di],01111000b
add di,2
loop sub1s
pop cx
pop di
pop es
pop ax
ret
sub3: push ax
push es
push ds
push di
push cx
mov ax,0b800h
mov es,ax
mov ds,ax
mov si,160
mov di,0
mov cx,24
sub3s: push cx
mov cx,160
cld
rep movsb
pop cx
mov si,0
mov cx,80
sub3ss: mov byte ptr es:[23*160+si],' '
add si,2
loop sub3ss
pop cx
pop di
pop ds
pop es
pop ax
ret
sjends:nop
code ends
end start

s0512

代码写的有点乱。

Μiss＾依然

......自学又是赶时间学，自学自用的、。。。

ycg

应该是mov bl,ah
而不是mov bh,ah吧

L]V[G

我来给个，注意事项注释什么的都有了，应该包含了你的疑问

1. ;编程：实现一个子程序setscreen，为显示输出提供如下功能：
   
2. ;(0) 清屏。
   
3. ;(1) 设置前景色。
   
4. ;(2) 设置背景色。
   
5. ;(3) 向上滚动一行。
   
6. ;
   
7. ;入口参数说明：
   
8. ;(1) 用 ah 寄存器传递功能号：0 表示清屏，1表示设置前景色，2 表示设置背景色，3 表示向上滚动一行；
   
9. ;(2) 对于2、3号功能，用 al 传送颜色值，(al) ∈{0,1,2,3,4,5,6,7}
   
10. 
    
11. assume cs:code
    
12. 
    
13. code segment
    
14. 
    
15. do0:       
    
16.                 push bx
    
17.                 push cx
    
18.                 push dx
    
19.                 push si
    
20.                 push di
    
21.                 push ds
    
22.                 push es
    
23.                
    
24.                 jmp short select      
    
25.                
    
26.         table dw sub1, sub2,sub3,sub4
    
27.           
    
28. select:
    
29.                 mov dl, al
    
30. 
    
31.                 cmp ah, 3
    
32.                 ja goiret      ;判断传递的是否大于 3
    
33.                
    
34.                 mov bl, ah
    
35.                 mov bh, 0
    
36.                 add bx, bx           ;根据ah中的功能号计算对应子程序的地址在table表中的偏移
    
37.                                                
    
38.                 call word ptr table[bx]            ;调用对应的功能子程序
    
39.                
    
40. goiret: pop es
    
41.                 pop ds
    
42.                 pop di
    
43.                 pop si
    
44.                 pop        dx
    
45.                 pop cx
    
46.                 pop bx
    
47.                
    
48.                 iret
    
49.                
    
50.                
    
51. ;功能子程序1：清屏               
    
52. sub1:   mov ax, 0b800h
    
53.                 mov es, ax
    
54.                 mov di, 0
    
55.                 mov cx, 2000
    
56.                
    
57.   sub1s:mov byte ptr es:[di], ' '
    
58.                 add di, 2
    
59.                 loop sub1s
    
60.                 ret
    
61.                
    
62.                
    
63. ;功能子程序2：设置前景色               
    
64. sub2:        mov ax, 0b800h
    
65.                 mov es, ax
    
66.                 mov di, 1
    
67.                 mov cx, 2000
    
68.   sub2s:and byte ptr es:[di], 11111000b
    
69.                 or es:[di], dl
    
70.                 add di, 2
    
71.                 loop sub2s
    
72.                 ret
    
73.                
    
74. 
    
75. ;功能子程序3：设置背景色               
    
76. sub3:       
    
77.                 mov cl, 4
    
78.                 shl dl, cl
    
79.                 mov ax, 0b800h
    
80.                 mov es, ax
    
81.                 mov di, 1
    
82.                 mov cx, 2000
    
83.   sub3s:and byte ptr es:[di], 10001111b
    
84.                 or es:[di], dl
    
85.                 add di, 2
    
86.                 loop sub3s
    
87.                 ret
    
88. 
    
89. 
    
90. ;功能子程序4：向上滚动一行               
    
91. sub4:        mov ax, 0b800h
    
92.                 mov ds, ax
    
93.                 mov si, 160        ;ds:si指向第n+1行
    
94.                
    
95.                 mov es, ax       ;es:di指向第n行
    
96.                 mov di, 0
    
97.                
    
98.                 cld
    
99.                 mov cx, 24      ;共复制24行
    
100.   sub4s:push cx
     
101.                 mov cx, 160
     
102.                 rep movsb     ;复制
     
103.                 pop cx
     
104.                 loop sub4s
     
105.                
     
106.                 mov cx, 80
     
107.                 mov di, 0
     
108.   sub4d:mov byte ptr es:[160*24+di], ' ' ;最后一行清空
     
109.                 add di, 2
     
110.                 loop sub4d
     
111.                 ret
     
112.                
     
113. doends: nop               
     
114. 
     
115. 
     
116. start:
     
117.                 mov ax, cs
     
118.                 mov ds, ax
     
119.                 mov si, offset do0      ;设置源地址
     
120.                
     
121.                 mov ax, 0
     
122.                 mov es, ax
     
123.                 mov di, 200h                        ;设置目标地址
     
124.                
     
125.                 cld                                                ;df置零
     
126.                 mov cx, offset doends - offset do0   
     
127.                 rep movsb                                 ;把do0放到目标地址 0：200h
     
128.                
     
129.                 mov ax, 0
     
130.                 mov es, ax
     
131.                 mov word ptr es:[7ch*4], 0      
     
132.                 mov word ptr es:[7ch*4+2], 20h   ;设置中断向量表
     
133.                                                                                  ;注意：此时 cs = 20h， ip = 0
     
134.                 mov ax, 4c00h
     
135.                 int 21h
     
136.                        
     
137. code ends
     
138. end start
     
139. 
     
140. 
     
141. 
     
142. ; 主程序：--------------------------------------------------------------
     
143. ; assume cs:code
     
144. ; ;入口参数说明：
     
145. ; ;(1) 用 ah 寄存器传递功能号：0 表示清屏，1表示设置前景色，2 表示设置背景色，3 表示向上滚动一行；
     
146. ; ;(2) 对于2、3号功能，用 al 传送颜色值，(al) ∈{0,1,2,3,4,5,6,7}
     
147. ; code segment
     
148. ; start:
     
149.                 ; mov ah,02h
     
150.                 ; mov al,04h
     
151.                 ; int 7ch
     
152.                
     
153.                 ; mov ax, 4c00h
     
154.                 ; int 21h
     
155. ; code ends
     
156. ; end start
     
157. ; -----------------------------------------------------------------------------
     
158. 
     
159. 
     
160. 
     
161. 
     
162. ;----------------------------------------------------------------------------------------               
     
163. ; 注意事项！！！！！！！！！：
     
164. ; 如果安装16.4给出的功能子程序的安装程序习惯采用下面图1安装结构会出问题，问题有两个:
     
165. 
     
166. ;问题1：  table dw sub1……中SUB1存放的应该是子程序的偏移地址，这个偏移地址是相对于中断程序入口的，
     
167. ;         而此时Sub1中存放的是相对于安装程序入口的地址。所以应该将被安装代码放到code段标号Start前边。
     
168. 
     
169.         ; assume cs:code
     
170.         ; code segment
     
171.                 ; start:
     
172.                         ; 安装程序
     
173.                 ; ；--------------------------
     
174.                 ; 被安装代码：
     
175.                 ; ；--------------------------
     
176.         ; code ends
     
177.         ; end start
     
178.           ; ==   图1   ==
     
179.                   
     
180. ; 问题2：在设置中断向量表的时候，0：[7ch*4]   Ip内存单元中的值应该设置为0，
     
181.                                ; 0:[7ch*4+2]  CS内存单元中的值应该设置为 20h
     
182.                                                           
     
183.                 ; 原因：这个虽然和一般设定 mov ax, 0
     
184.                                          ; mov es, ax
     
185.                                                                  ; mov word ptr es:[7ch*4], 200h
     
186.                                                                  ; mov word ptr es:[7ch*4+2], 0
     
187.                                                                  
     
188.                 ; 内存单元是一样的，都能找到目标中断程序的入口，但是，如果按照第二种方法
     
189.                 ; 在主程序调用中断程序int7的时候，
     
190.                 ; 相当于 (IP) = (n*4) = 200，（cs） = (n*4+2) = 0
     
191.                        
     
192.                 ; 于是 在执行中断程序中的 call word ptr table[bx],的过程中，当前的cs为0，ip为某个值
     
193.                 ; 这个指令相当于 push ip, jmp cs:[table+bx]，cs为0，那么内存空间0:[table+bx]为未知，程序出错
     
194.                
     
195.                 ; 如果按照第一种做法，此时cs:[table+bx], 是内存空间 20h:[table+bx], 是我们想得到的结果
     

复制代码

，我自己敲的

阔怀

{:1_1:}