为什么win32汇编写的helloword程序不显示窗口，只在后台运行！？

大笨钟

很简单的问题，麻烦大家帮忙看一下。搞定了5鱼币作为答谢，~

小甲鱼

犯了一些比较简单的错误，例如字符串在汇编代码是单引号，不是双引号等，贴我视频中的源码供参考：

1. ;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
   
2. ; Sample code for < Win32ASM Programming 2nd Edition>
   
3. ; by 罗云彬, http://asm.yeah.net
   
4. ; change by 小甲鱼, http://www.fishc.com
   
5. ;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
   
6. ; FirstWindow.asm
   
7. ; 窗口程序的模板代码
   
8. ;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
   
9. ; 使用 nmake 或下列命令进行编译和链接:
   
10. ; ml /c /coff FirstWindow.asm
    
11. ; Link /subsystem:windows FirstWindow.obj
    
12. ;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
    
13.                 .386
    
14.                 .model flat,stdcall
    
15.                 option casemap:none
    
16. ;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
    
17. ; Include 文件定义
    
18. ;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
    
19. include                windows.inc
    
20. include                gdi32.inc
    
21. includelib        gdi32.lib
    
22. include                user32.inc
    
23. includelib        user32.lib
    
24. include                kernel32.inc
    
25. includelib        kernel32.lib
    
26. ;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
    
27. ; 数据段
    
28. ;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
    
29.                 .data?
    
30. hInstance        dd                ?
    
31. hWinMain        dd                ?
    
32. 
    
33.                 .const
    
34. szClassName                db        'MyClass',0
    
35. szCaptionMain        db        'My first Window !',0
    
36. szText                        db        'Welcome to fishc.com!',0
    
37. ;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
    
38. ; 代码段
    
39. ;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
    
40.                 .code
    
41. ;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
    
42. ; 窗口过程
    
43. ;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
    
44. _ProcWinMain        proc        uses ebx edi esi hWnd,uMsg,wParam,lParam
    
45.                 local        @stPs:PAINTSTRUCT
    
46.                 local        @stRect:RECT
    
47.                 local        @hDc
    
48. 
    
49.                 mov        eax,uMsg
    
50. ;********************************************************************
    
51.                 .if        eax ==        WM_PAINT
    
52.                         invoke        BeginPaint,hWnd,addr @stPs
    
53.                         mov        @hDc,eax
    
54. 
    
55.                         invoke        GetClientRect,hWnd,addr @stRect
    
56.                         invoke        DrawText,@hDc,addr szText,-1,\
    
57.                                 addr @stRect,\
    
58.                                 DT_SINGLELINE or DT_CENTER or DT_VCENTER
    
59. 
    
60.                         invoke        EndPaint,hWnd,addr @stPs
    
61. ;********************************************************************
    
62.                 .elseif        eax ==        WM_CLOSE
    
63.                         invoke        DestroyWindow,hWinMain
    
64.                         invoke        PostQuitMessage,NULL
    
65. ;********************************************************************
    
66.                 .else
    
67.                         invoke        DefWindowProc,hWnd,uMsg,wParam,lParam
    
68.                         ret
    
69.                 .endif
    
70. ;********************************************************************
    
71.                 xor        eax,eax
    
72.                 ret
    
73. 
    
74. _ProcWinMain        endp
    
75. ;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
    
76. _WinMain        proc
    
77.                 local        @stWndClass:WNDCLASSEX
    
78.                 local        @stMsg:MSG
    
79. 
    
80.                 invoke        GetModuleHandle,NULL
    
81.                 mov        hInstance,eax
    
82.                 invoke        RtlZeroMemory,addr @stWndClass,sizeof @stWndClass
    
83. ;********************************************************************
    
84. ; 注册窗口类
    
85. ;********************************************************************
    
86.                 invoke        LoadCursor,0,IDC_ARROW
    
87.                 mov        @stWndClass.hCursor,eax
    
88.                 push        hInstance
    
89.                 pop        @stWndClass.hInstance
    
90.                 mov        @stWndClass.cbSize,sizeof WNDCLASSEX
    
91.                 mov        @stWndClass.style,CS_HREDRAW or CS_VREDRAW
    
92.                 mov        @stWndClass.lpfnWndProc,offset _ProcWinMain
    
93.                 mov        @stWndClass.hbrBackground,COLOR_WINDOW + 1
    
94.                 mov        @stWndClass.lpszClassName,offset szClassName
    
95.                 invoke        RegisterClassEx,addr @stWndClass
    
96. ;********************************************************************
    
97. ; 建立并显示窗口
    
98. ;********************************************************************
    
99.                 invoke        CreateWindowEx,WS_EX_CLIENTEDGE,offset szClassName,offset szCaptionMain,\
    
100.                         WS_OVERLAPPEDWINDOW,\
     
101.                         100,100,600,400,\
     
102.                         NULL,NULL,hInstance,NULL
     
103.                 mov        hWinMain,eax
     
104.                 invoke        ShowWindow,hWinMain,SW_SHOWNORMAL
     
105.                 invoke        UpdateWindow,hWinMain
     
106. ;********************************************************************
     
107. ; 消息循环
     
108. ;********************************************************************
     
109.                 .while        TRUE
     
110.                         invoke        GetMessage,addr @stMsg,NULL,0,0
     
111.                         .break        .if eax        == 0
     
112.                         invoke        TranslateMessage,addr @stMsg
     
113.                         invoke        DispatchMessage,addr @stMsg
     
114.                 .endw
     
115.                 ret
     
116. 
     
117. _WinMain        endp
     
118. ;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
     
119. start:
     
120.                 call        _WinMain
     
121.                 invoke        ExitProcess,NULL
     
122. ;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
     
123.                 end        start
     

复制代码

大笨钟

着急啊，谢谢各位

大笨钟

小甲鱼 发表于 2013-1-28 00:35

                               
登录/注册后可看大图

犯了一些比较简单的错误，例如字符串在汇编代码是单引号，不是双引号等，贴我视频中的源码供参考：

你视频里的源代码我都有………………我把双引号改为单引号还是有错啊，有个人告诉我是窗口过程中的错误，我实在看不出来

大笨钟

错误找到了，是窗口过程的 xor eax ,eax 这个语句应该去掉，谢谢各位！

大笨钟

小甲鱼 发表于 2013-1-27 16:10

                               
登录/注册后可看大图

犯了一些比较简单的错误，例如字符串在汇编代码是单引号，不是双引号等，贴我视频中的源码供参考：

弱弱地告诉小鲫鱼，单引号和双引号都行：）

小甲鱼

大笨钟 发表于 2013-1-28 12:27

                               
登录/注册后可看大图

弱弱地告诉小鲫鱼，单引号和双引号都行：）

哈哈，我自己犯了习惯性错误~