实验7程序问题求助

NO.1_SPEED

    关于小甲鱼老师的《零基础学习汇编语言程序设计》中的实验7，我的程序代码如下：

assume cs:code,ds:data,es:table

data segment

        db '1975','1976','1977','1978','1979','1980','1981','1982','1983'
        db '1984','1985','1986','1987','1988','1989','1990','1991','1992'
        db '1993','1994','1995'
        ;以上表示21年的21个字符串
        
        dd 16,22,382,1356,2390,8000,16000,24486,50065,97479,140417,197514
        dd 345980,590827,803530,1183000,1843000,2759000,3753000,4649000,5937000
        ;以上是表示21年公司总司总收入的21个dword型数据
        
        dw 3,7,9,13,28,38,130,220,476,778,1001,1442,2258,2793,4037,5635,8226
        dw 11542,14430,15257,17800
        ;以上是表示21年公司雇员人数的21个word型数据
        
data ends

table segment
        db 21 dup ('year summ ne ?? ')
table ends

code segment

start:        mov ax,data
                mov ds,ax
                mov ax,table
                mov es,ax
                
                mov bx,0
                mov si,0
                
                mov cx,21
                
l:                mov ax,[bx]
                mov es:[si],ax
                mov ax,2[bx]
                mov es:2[si],ax
                ;以上将年份存储到table段中
                
                mov ax,84[bx]
                mov es:5[si],ax
                mov ax,86[bx]
                mov es:7[si],ax
                ;以上将总收入放到table段中
                
                mov ax,168[bx]
                mov es:10[si],ax
                ;以上将人数放到table段中
                
                mov ax,es:5[si]
                mov dx,es:7[si]
                
                div word ptr es:10[si]
                mov es:13[si],ax
                ;以上计算人均收入
                
                add bx,4
                add si,16
                
                loop l
                
                mov ax,4c00h
                int 21h
                
code ends

end start
        

   程序编译链接都没有问题，debug时按t命令逐条运行后第一次循环完成在loop指令处用p命令时会出现“Divide overflow”的溢出报错，用d命令查看table段中的内容发现程序只运行到1986年处后面的并没有运行。究竟是什么问题一直没有找出，请各位朋友给予帮助。谢谢大家！
特此指出我是在win7中的xp mode下调试的。

L]V[G

主要是 48，49两行存在逻辑问题，人数是字型数据占2个字节，但是在你的循环里每次bx+4，所以没有把全部人数放到目标地址
你的大思路是正确的，下面我给一个我自己写的程序，总体的和你的差不多
区别就是把人数一部分独立出来，先传送到目标地址

assume cs:code,ds:data,es:table ;2013年2月6日 12:47:27
                                ;目的：汇编实验7
data segment
    db '1975','1976','1977','1978','1979','1980','1981','1982','1983'
    db '1984','1985','1986','1987','1988','1989','1990','1991','1992'
    db '1993','1994','1995'
    ;年份，共占84个字节，在内存空间：data：0--data：83
                                           ;data：0--data：53h
    dd 16,22,382,1356,2390,8000,16000,24486,50065,97479,140417,197514
    dd 345980,590827,803530,1183000,1843000,2759000,3753000,4649000,5937000
    ;收入，共占84个字节，在内存空间：data：84--data：167
                                          ;data：54h--data：a7h
    dw 3,7,9,13,28,38,130,220,476,778,1001,1442,2258,2793,4037,5635,8226
    dw 11452,14430,15257,17800
        ;人数，共占42个字节，在内存空间：data：168--data：209
                                          ;data：a8h--data：d1h
data ends

table segment
    db 21 dup ('year summ ne ?? ')
table ends

code segment
start:
      mov ax,data
          mov ds,ax
          
          mov ax,table
          mov es,ax
          
          mov si,0
          mov di,0
          mov cx,21
   s0:mov ax,[bx].168[si] ;s0循环把每个人数放进目标地址
      mov es:0ah[di],ax
          add si,2
          add di,16
          loop s0
   
      mov si,0
          mov di,0
          mov cx,21
   s1:mov ax,[bx].0[si] ;把每个年份放到目标地址
      mov es:0[di],ax
      mov ax,[bx].2[si]
          mov es:2[di],ax
          
          mov ax,[bx].84[si] ;把每个收入放到目标地址
      mov es:5[di],ax
          mov ax,[bx].86[si]
          mov es:7[di],ax
          
          mov ax,es:5[di]  ;把每个平均收入计算出来，放到目标地址
      mov dx,es:7[di]
          div word ptr es:0ah[di]
          mov es:0dh[di],ax
          
          add si,4
          add di,16
          loop s1
          
          mov ax,4c00h
          int 21h
code ends

end start
          

NO.1_SPEED

L]V[G 发表于 2013-3-2 23:58

                               
登录/注册后可看大图

主要是 48，49两行存在逻辑问题，人数是字型数据占2个字节，但是在你的循环里每次bx+4，所以没有把全部人数 ...

就是这个问题 当时想错了 谢谢您！:handshake