关于王爽的《汇编语言》实验七的问题。

H云淡风清

这是我写的程序，但是debug中看好像只有年份和收入被复制到table段，不知道是什么问题，求解。

assume cs:code,ss:stack
data segment
        db '1975','1976','1977','1978','1979','1980','1981','1982','1983'
        db '1984','1985','1986','1987','1988','1989','1990','1991','1992'
        db '1993','1994','1995'
        ;以上是年份
        
        dd 16,22,382,1356,2390,8000,16000,24486,50065,97479,410417,197514
        dd 345980,590827,803530,1183000,1843000,2759000,3753000,4649000,5937000
        ;以上是收入
        
        dw 3,7,9,13,28,38,130,220,476,778,1001,1442,2258,2758,2793,4037,5635,8226
        dw 1154,1443,1525,1780
        ;以上是员工人数
data ends
stack segment
        dw 8 dup(0)  ;定义16个字节栈空间以供暂存数据
stack ends
table segment
        db 21 dup ('year sume ne ?? ')  
table ends
code segment
start:
        ;初始化部分
        mov ax,data
        mov ds,ax
        mov ax,stack
        mov ss,ax
        mov ax,table
        mov es,ax
        mov bx,0
        mov si,0

        mov cx,21
s:        
        ;复制年份
        mov ax,ds:[bx+0]
        mov es:[si+0],ax
        mov ax,ds:[bx+2]
        mov es:[si+2],ax
        
        ;加空格
        mov byte ptr es:[si+4],20h
        
        ;复制收入
        mov ax,ds:[bx+84]
        mov es:[si+5],ax
        mov ax,ds:[bx+86]
        mov es:[si+7],ax
        
        ;加空格
        mov byte ptr es:[si+9],20h
        
        ;复制员工数
        mov ax,ds:[bx+168]
        mov es:[si+10],ax
        
        ;加空格
        mov byte ptr es:[si+12],20h
        
        ;计算人均收入并送入table段中
        mov ax,ds:[bx+84]
        mov dx,ds:[bx+86]
        div word ptr ds:[bx+168]
        mov es:[si+13],ax
        
        ;加空格
        mov byte ptr es:[si+15],20h
        
        ;定位下一数据
        add si,16
        add bx,4
        
        loop s
        mov ax,4c00h
        int 21h
code ends
end start

H云淡风清

这个怎么编译不通过呢？

assume cs:code,ds:data
data segment
        db '1975','1976','1977','1978','1979','1980','1981','1982','1983'
        db '1984','1985','1986','1987','1988','1989','1990','1991','1992'
        db '1993','1994','1995'
        ;年份
        
        dd 16,22,382,1356,2390,8000,16000,24486,50065,97479,410417,197514
        dd 345980,590827,803530,1183000,1843000,2759000,3753000,4649000,5937000
        ;收入
        
        dw 3,7,9,13,28,38,130,220,476,778,1001,1442,2258,2758,2793,4037,5635,8226
        dw 1154,1443,1525,1780
        ;员工人数
data ends
table segment
        db 21 dup ('year sume ne ?? ')  
table ends
code segment
start:
        ;初始化部分
        mov ax,data
        mov ds,ax
        mov ax,table
        mov es,ax
        mov bx,0
        mov si,0
        mov di,0
        
        mov cx,21
s:
        ;复制年份
        mov ax,[bx]
        mov es:[si],ax
        mov ax,[bx+2]
        mov es:[si+2],ax
        
        ;加空格
        mov byte ptr es:[si+4],20h
        
        ;复制收入
        mov ax,[bx+84]
        mov es:[si+5],ax
        mov ax,[bx+86]
        mov es:[si+7],ax
        
        ;加空格
        mov byte ptr es:[si+9],20h
        
        ;复制雇员数
        mov ax,ds:[di+168]
        mov es:[si+10],ax
        
        ;加空格
        mov byte ptr es:[si+12],20h
        
        ;计算人均收入
        mov ax,[bx+84]
        mov dx,[bx+86]
        div word ptr ds:[di+168]
        mov es:[si+13],ax
        
        ;加空格
        mov byte ptr es:[si+15],20h
        
        add bx,4
        add si,16
        add di,2
        
        loop s
        mov ax,4c00h
        int 21h
code ends
end start

smkill

同意楼上的,显然申明了没用,用了没有申明!

364063141

支持鱼C，顶一下

KTMONREK

我也是一样，只有年份

KTMONREK

我终于知道为什么了，注意定义数据时年份是字符串，传进cpu里面的是ascii码，比如'1937'，就是31h,39h,33h,37h，在内存中看到的就是ascii码，然后在右边会显示对应的十进制数码值，然后后边定义的收入，雇员数都是直接定义的数字，比如dd 16，这里的16是十进制数，传入cpu里面就是00000010h(双字型数据)，所以在内存中从左往右看到的是10 00 00 00，从内存中可以看到我们的确把数据传进了table段中，但是10h在ascii码中不代表人和字符，所以不会在右边显示出来，0~9的ascii码是30h~39h，所以只有内存中的数值是30h~39h才会在右边显示出0~9的数字。所以我们只能看到年份，但是看不到其他数据，但是它们的的确确存到了内存单元中。