第九章，实验9 将字符串写入显存，分别以不同的颜色显示

为之疯狂

assume cs:code,ds:data,ss:stack


data segment

        db 'welcome to masm!'  ;定义要显示的字符串(共16字节)
        db 02h,24h,71h         ;定义三种颜色属性

data ends
 

stack segment

        dw 8 dup(0)

stack ends


code segment

start:
        mov ax,data                ;将ds指向 数据段
        mov ds,ax
                
        mov ax,stack        ;将ss指向 栈段
        mov ss,ax
        mov sp,10h                ;设置 栈顶

                xor bx,bx                        ;bx清零,用来索引颜色
                
                ;一行有80个字符，每个字符占2个字节,中间第32个 (11*80*2)+(32*2) = 720h  把他当成短地址 右边减一位
        mov ax,0b872h            ;算出屏幕第12行中间的显存的段起始位置放入ax中
                
        mov cx,3                     ;S3循环控制行数，外循环为3次，因为要显示三个字符串
s3:     push cx                        ;三个进栈操作为外循环s3保存相关寄存器的值
        push ax                        ;以防止它们的值在内循环中被破坏
        push bx
                
        mov es,ax                      ;此时es为屏幕第12行中间的显存的段起始位置
                
        mov si,0                        ;si用来索引代码列的字符
        mov di,0                        ;di用来定位目标列

        mov cx,16                     ;S1循环控制存放的字符，内循环16次，因为一个字符串中含16个字节
s1:     mov al,ds:[si]                ;取出每一个字符
        mov es:[di],al                ;写入每一个字符
        inc si                                ;si是源数据的偏移地址，是以字节为单位所以+1就ok了
                
        add di,2                        ;0 2 4 6 8 偶数存放的是ascii码,也就是每一个单词  
                                                        ;di是目标空间的偏移地址,，是以字为单位,所以+2，因为显存低字节存放的是字符,高字节存放的是属性
        loop s1                                      ;此循环实现偶地址中存放字符
        
        mov di,1                                  ;1 3 5 7 9 存放的是属性，也就是颜色
                                                                ;di的值设为1,从而为在显存奇地址中存放字符的颜色属性做准备
                pop bx                                        ;这里其实bx ，没有修改过
        mov al,ds:10h[bx]           ;取颜色属性 10h = 16 , 0-15存放的是数据 16 存放的是颜色
                inc bx                                        ;颜色也是字节，所以偏移+1
                
                
        mov cx,16                             ;第二个内循环也为16次
s2:     mov es:[di],al                        ;颜色永远存放在al中,只要将颜色填补到每一个单词的属性中去就行了，也就是单词的高字节是基数 1 3 5 7……
        add di,2
        loop s2                               ;此循环实现奇地址中存放字符的颜色属性
        
        ;以下4句为下一趟外循环做准备
        pop ax                                        ;取出显存的段地址
        add ax,0ah                           ;将显存的段起始地址设为当前行的下一行
                                                                ;[在段地址中加0ah,相当于在偏移地址中加了0a0h(=160d)]
        pop cx                                        ;取出外层循环的循环次数，也就是还原循环次数
        loop s3                                        ;第一行单词写入完毕，继续写入第二行
        

        mov ax,4c00h
        int 21h

code ends

end start

为之疯狂

希望版主能够看到这条信息，我刚刚无意中看到一个bug，在发帖的时候，帖子类型竟然可以直接选择  已经解决 ，个人认为这个不应该在  帖子类型  里面显示。