|
|
发表于 2014-7-21 10:25:17
|
显示全部楼层
本帖最后由 メ㊣逆ご帅☆ 于 2014-7-21 19:44 编辑
如果没时间可以直接跳到下面红色部分，为楼主要的内容，下面为书上的完整源码
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; Sample code for < Win32ASM Programming 3rd Edition>
; by 罗云彬, http://www.win32asm.com.cn
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; Hookdll.asm
; 键盘钩子使用的 dll 程序
; 用来方置钩子过程
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; 使用 nmake 或下列命令进行编译和链接:
; ml /c /coff Hookdll.asm
; Link /subsystem:windows /section:.bss,S /Def:Hookdll.def /Dll Hookdll.obj
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
.386
.model flat, stdcall
option casemap :none
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; Include 文件定义
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
include windows.inc
include user32.inc
includelib user32.lib
include kernel32.inc
includelib kernel32.lib
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
.data
hInstance dd ?
.data?
hWnd dd ?
hHook dd ?
dwMessage dd ?
szAscii db 4 dup (?)
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
.code
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; dll 的入口函数
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
DllEntry proc _hInstance,_dwReason,_dwReserved
push _hInstance
pop hInstance
mov eax,TRUE
ret
DllEntry Endp
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; 键盘钩子回调函数
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
HookProc proc _dwCode,_wParam,_lParam
local @szKeyState[256]:byte
invoke CallNextHookEx,hHook,_dwCode,_wParam,_lParam
invoke GetKeyboardState,addr @szKeyState
invoke GetKeyState,VK_SHIFT
mov @szKeyState + VK_SHIFT,al
mov ecx,_lParam
shr ecx,16
invoke ToAscii,_wParam,ecx,addr @szKeyState,addr szAscii,0
mov byte ptr szAscii [eax],0
invoke SendMessage,hWnd,dwMessage,dword ptr szAscii,NULL
xor eax,eax
ret
HookProc endp
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; 安装钩子
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
InstallHook proc _hWnd,_dwMessage
push _hWnd
pop hWnd
push _dwMessage
pop dwMessage
invoke SetWindowsHookEx,WH_KEYBOARD,addr HookProc,hInstance,NULL
mov hHook,eax
ret
InstallHook endp
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; 卸载钩子
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
UninstallHook proc
invoke UnhookWindowsHookEx,hHook
ret
UninstallHook endp
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
End DllEntry
invoke SetWindowsHookEx,WH_KEYBOARD,addr HookProc,hInstance,NULL
从这里入手
可以看到钩子的回调函数式这里指定的
百度:SetWindowsHookEx
打开百度百科nCode参数是Hook代码，Hook子程使用这个参数来确定任务。这个参数的值依赖于Hook类型，每一种Hook都有自己的Hook代码特征字符集。
wParam和lParam参数的值依赖于Hook代码，但是它们的典型值是包含了关于发送或者接收消息的信息。
意思就是钩子的类型（SetWindowsHookEx的第一个参数）决定了nCode参数的作用
同样的钩子的类型又决定了wParam和lParam参数
对于键盘钩子WH_KEYBOARD来说
借用书上《琢玉成器XXXXXXX》原话。还有同样百度查查CallNextHookEx,GetKeyboardState,GetKeyState等API的资料
（补充说明下CallNextHookEx(书上解释的可能更清楚。楼主可以看下)。作用是执行下一个钩子子程，为什么要这么干。可以看这张图
物理击键 ↓ 钩子A ↓ 钩子B ↓ 钩子C ↓ 钩子D ↓ Window的消息处理函数
以键盘钩子为例。WINDOWS允许存在多个同类型的钩子。
比如程序A一个。程序B一个。没有说一个程序挂钩了就不允许另外一个程序挂钩。
这里假设我的钩子是钩子A。
我的钩子处理完后需要调用下一个钩子。
如果不调用。那么钩子B C D 以及WINDOW的消息处理函数均不会被调用，
那很糟糕。
CallNextHookEx就是来完成这一使命的（调用顺序按照钩子链来，具体看书）
）
可以得出以下注释、、、、、、、、、、、、、、、、、、、、、、、
事实上还省略了蛮多查资料的细节。希望楼主能更好的使用搜索引擎和书
天啊，我码完怎么变成乱码了，所以发图片了（可能我理解有部分错误。供参考），写的比较急所以可能说的不是那么清楚让人明白建议看
《琢玉成器XXXXXXX》第11章很详细的
mov @szKeyState + VK_SHIFT,al ;特别是这一句再补充下，举个类似的例子
比如我在一个房间里面，有四个方向的门。
我有个函数。
可以判断不同方向门是否通行。
我会对四个方向的门进行通行判断。然后我要存储起来门的通行状态
这时候定义一个四个字节的变量
DWORD 通行FLAG;4字节分别存储不同方向的状态
然后再进行以下——人为——定义，注意是人为的
0代表上方向的门
1代表下方向的门
2代表左方向的门
3代表右方向的门
那么[通行FLAG指针(又或者说内存地址)+0]存储的就是上方向门的通行状态
[通行FLAG指针(又或者说内存地址)+1]为下方向的门的通行状态
那么上面的VK值就跟这里的0 1 2 3类似。方便存储和读取。算是一种结构
如果你了解或者学习过C/C++语法。那么这样更简单理解
写个伪代码
#define 上 0
#define 下 1
#define 左 2
#define 右 3
DWORD 通行FLAG[4]={0};
BOOL 检测通行(int 方向)//0为不可通行，1为可通行
{
XXXXXX
}
void MyCheck()
{
int 状态;
状态=检测通行(上);
通行FLAG[上]=状态;
状态=检测通行(下）;
通行FLAG[下]=状态;
状态=检测通行(左);
通行FLAG[左]=状态;
状态=检测通行(右);
通行FLAG[右]=状态;
}
可以发现这样很方便存储取出数据
不用记住0 1 2 3 的含义。记住 上 下 左 右就可以了
|
|
( 粤ICP备18085999号-1 | 粤公网安备 44051102000585号)
狗仔卡
发表于 2014-7-21 10:25:16
置顶卡
千斤顶
显身卡
楼主